(VB.NET) Get eBay Application Token

This example shows how to request an eBay Application token.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' See the Ebay documentation about Access token types
' Also see the Ebay documentation about client credentials grant flow

Dim http As New Chilkat.Http

' If using the sandbox, the target endpoint will be:
' POST https://api.sandbox.ebay.com/identity/v1/oauth2/token

' If using the production (live) system, the target endpoint will be:
' POST https://api.ebay.com/identity/v1/oauth2/token

' The eBay client_id and client_secret needs to be sent
' in a Basic Authorization  request header, which has this format:
' Authorization: Basic <B64_encoded_oauth_credentials>

' Chilkat takes care of it.  You only need to set the Login = client_id,
' and password = client_secret, and indicate you want "Basic" HTTP Authorization.
http.Login = "EBAY_CLIENT_ID"
http.Password = "EBAY_CLIENT_SECRET"
http.BasicAuth = True

' Let's do the following POST:

'   HTTP method:   POST
'   URL (Sandbox): https://api.sandbox.ebay.com/identity/v1/oauth2/token
' 
'   HTTP headers:
'     Content-Type = application/x-www-form-urlencoded
'     Authorization = Basic <B64-encoded-oauth-credentials>
' 
'   Request body (wrapped for readability):
'     grant_type=client_credentials&
'     redirect_uri=<RuName-value>&
'     scope=<SPACE separated list of scopes>
' 

' Create an HttpRequest object to hold the request params.
Dim req As New Chilkat.HttpRequest
req.HttpVerb = "POST"
req.AddParam("grant_type","client_credentials")

' The scope query param indicates the access to be provided by the token.
' Multiple scopes can be specified by separating each with a SPACE char.
' See the Ebay OAuth scopes documentation

req.AddParam("scope","https://api.ebay.com/oauth/api_scope")

' (The PostUrlEncoded method automatically sets the Content-Type header equal to "application/x-www-form-urlencoded")
Dim endPoint As String = "https://api.sandbox.ebay.com/identity/v1/oauth2/token"
Dim resp As Chilkat.HttpResponse = http.PostUrlEncoded(endPoint,req)
If (http.LastMethodSuccess <> True) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


' The response is JSON..
Dim json As New Chilkat.JsonObject
json.Load(resp.BodyStr)
json.EmitCompact = False

' If the response status code is not 200, then it failed.
Debug.WriteLine("Response status code = " & resp.StatusCode)
If (resp.StatusCode <> 200) Then
    Debug.WriteLine(json.Emit())
    Debug.WriteLine("Failed.")
    Exit Sub
End If


' We successfully retrieved an eBay access token.
' The actual access token string can be parsed from the JSON like this:
Dim accessToken As String = json.StringOf("access_token")

' This application token is only valid for 7200 seconds (2 hours).  We'll want to refresh
' it before it expires.  (There is an online example for that..)
' For now, let's save the JSON to a file for our application to use.

' But before doing that, let's add to the JSON an expiration timestamp
' so we know when to refresh the token.
Dim dtExpire As New Chilkat.CkDateTime
dtExpire.SetFromCurrentSystemTime()
dtExpire.AddSeconds(json.IntOf("expires_in"))
json.AppendString("expire_time",dtExpire.GetAsTimestamp(False))

' Persist the JSON to a file.
Dim fac As New Chilkat.FileAccess
Dim success As Boolean = fac.WriteEntireTextFile("qa_data/tokens/ebay.json",json.Emit(),"utf-8",False)
If (success <> True) Then
    Debug.WriteLine(fac.LastErrorText)
    Debug.WriteLine("Failed to save eBay Application token to file.")
    Exit Sub
End If


Debug.WriteLine(json.Emit())
Debug.WriteLine("Success.")

' The output of this example is:

' 	{ 
' 	  "access_token": "v^1.1#i^1#p^1#I^3#r^0# ... Ajp1BQhJDgAA",
' 	  "token_type": "Application Access Token",
' 	  "expires_in": 7200,
' 	  "refresh_token": "N/A",
' 	  "expire_time": "2017-04-16T14:44:20Z"
' 	}
' 
' 	Success.
'