(VB.NET) Download File from Dropbox into a String Variable

Demonstrates how to download a file from Dropbox directly into a string variable.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' A Dropbox access token should have been previously obtained.
' Dropbox access tokens do not expire.
' See Dropbox Access Token.

Dim rest As New Chilkat.Rest

' Connect to Dropbox
Dim success As Boolean = rest.Connect("content.dropboxapi.com",443,True,True)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Add request headers.
rest.AddHeader("Authorization","Bearer DROPBOX_ACCESS_TOKEN")

' The download "parameters" are contained in JSON passed in an HTTP request header.
' This is the JSON indicating the file to be downloaded:
' { 
'    "path": "/jack.txt",
' }


Dim json As New Chilkat.JsonObject
json.AppendString("path","/jack.txt")
rest.AddHeader("Dropbox-API-Arg",json.Emit())

' The content of the file on Dropbox is returned.
Dim fileContent As String = rest.FullRequestNoBody("POST","/2/files/download")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, Dropbox responds with a 200 response code.
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body (if any): " & fileContent)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    Exit Sub
End If


' Show the file content that was downloaded:
Debug.WriteLine(fileContent)
Debug.WriteLine("----")

' Information about the downloaded file is also available as JSON in a response header.
' The "dropbox-api-result" response header contains the information.  For example:
Dim apiResult As String = rest.ResponseHdrByName("dropbox-api-result")
Debug.WriteLine(apiResult)

' In this case, the pretty-formatted dropbox-api-result JSON looks like this:
' { 
'   "name": "jack.txt",
'   "path_lower": "/jack.txt",
'   "path_display": "/jack.txt",
'   "id": "id:yqx4-tE_NKAAAAAAAAAAAQ",
'   "client_modified": "2016-06-02T20:42:11Z",
'   "server_modified": "2016-06-02T20:42:11Z",
'   "rev": "8482db15f",
'   "size": 42
' }

' Load the JSON, pretty-print it, and demonstrate how to get some values...
Dim jsonResult As New Chilkat.JsonObject
jsonResult.EmitCompact = False
jsonResult.Load(apiResult)
' Show the JSON pretty-printed...
Debug.WriteLine(jsonResult.Emit())

' Sample code to get data from the JSON response:
Dim size As Integer = jsonResult.IntOf("size")
Debug.WriteLine("size = " & size)

Dim rev As String = jsonResult.StringOf("rev")
Debug.WriteLine("rev = " & rev)

Dim clientModified As String = jsonResult.StringOf("client_modified")
Dim ckdt As New Chilkat.CkDateTime
ckdt.SetFromTimestamp(clientModified)
Dim bLocalTime As Boolean = True
Dim dt As Chilkat.DtObj = ckdt.GetDtObj(bLocalTime)
Debug.WriteLine(dt.Day & "/" & dt.Month & "/" & dt.Year & " " & dt.Hour & ":" & dt.Minute)