VB.NET

Box.com Streaming Upload File

See more Box Examples

Demonstrates how to upload a file to box.com, streaming the file directly from the filesystem.

Note: This example requires a fix that is included in Chilkat v9.5.0.70 and above.

VB.NET

Dim success As Boolean = False

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

'   Provide a previously obtained OAuth2 access token.
Dim oauth2 As New Chilkat.OAuth2
oauth2.AccessToken = "BOX_ACCESS_TOKEN"
rest.SetAuthOAuth2(oauth2)

' First, make the initial connection.
' A single REST object, once connected, can be used for many Box REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim bAutoReconnect As Boolean = True

' ----------------------------------------------------------------------
' IMPORTANT: Note that the domain is "upload.box.com", not "api.box.com"
' ----------------------------------------------------------------------
success = rest.Connect("upload.box.com",443,True,bAutoReconnect)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' The request body uses the "multipart/form-data" format to transmit two "parts". 
' The first part is called "attributes" and contains a JSON object with information about the file, including the name of the file 
' and the ID of the parent folder. The second part contains the contents of the file. 
' (Note that the name of the second "part" is ignored.)

rest.AddHeader("Content-Type","multipart/form-data")

' Provide the content for each part of the request...

' First the JSON attributes.  Use "0" for the root folder.
'   {"name":"hedgehogs.jpg", "parent":{"id":"0"}}
Dim jsonAttr As New Chilkat.JsonObject
jsonAttr.UpdateString("name","hedgehogs.jpg")
jsonAttr.UpdateString("parent.id","0")

rest.PartSelector = "1"
rest.AddHeader("Content-Disposition","form-data; name=""attributes""; ")
rest.SetMultipartBodyString(jsonAttr.Emit())

' The upload will stream directly from a file.
rest.PartSelector = "2"
rest.AddHeader("Content-Disposition","form-data; name=""file""; filename=""hedgehogs.jpg""")
' "application/octet-stream" can be safely used for any type file..
rest.AddHeader("Content-Type","application/octet-stream")

' IMPORTANT: This example requires Chilkat v9.5.0.70 or later, for a fix that was made in
' multipart/streaming uploads. 
Dim fileStream As New Chilkat.Stream
fileStream.SourceFile = "qa_data/jpg/hedgehogs.jpg"
rest.SetMultipartBodyStream(fileStream)

' Restore the PartSelector to "0" (for safety, in case something else sends another request on this object)
rest.PartSelector = "0"

' Send the multipart/form-data request, which uploads the file by streaming directly from the filesystem.
Dim responseBody As String = rest.FullRequestMultipart("POST","/api/2.0/files/content")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' A 201 is received for a successful upload
If (rest.ResponseStatusCode <> 201) Then
    Debug.WriteLine("Box.com upload failed.")
    Debug.WriteLine("Request header:")
    Debug.WriteLine(rest.LastRequestHeader)
    Debug.WriteLine("---")
    Debug.WriteLine("Response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("Response body:")
    Debug.WriteLine(responseBody)
    Exit Sub
End If


Debug.WriteLine("File uploaded.")