(VB.NET) Upload File in Blocks (with Content-MD5 header) and Commit the Block List

Demonstrates how to upload a file in blocks and then commit the block list. This example includes a Content-MD5 header for each block.

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' Azure Blob Service Example: Upload a file in blocks, and then commit the block list.
' See also: https://msdn.microsoft.com/en-us/library/azure/dd135726.aspx

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

' Connect to the Azure Storage Blob Service
Dim bTls As Boolean = True
Dim port As Integer = 443
Dim bAutoReconnect As Boolean = True
' In this example, the storage account name is "chilkat".
Dim success As Boolean = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Provide Azure Cloud credentials for the REST call.
Dim azAuth As New Chilkat.AuthAzureStorage
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2020-08-04" header to be automatically added.
azAuth.XMsVersion = "2020-08-04"
success = rest.SetAuthAzureStorage(azAuth)

' Note: The application does not need to explicitly set the following
' headers: Content-Length, x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.


' As the blocks are uploaded, we'll keep an XML block list for the subsequent commit..
Dim xml As New Chilkat.Xml
xml.Tag = "BlockList"

' Any type of file can be uploaded in this way.  It can a text file, binary file, anything...
' This example will upload an XML file that is approximately 275K in size.  It can be downloaded
' at http://www.chilkatsoft.com/hamlet.xml
Dim fac As New Chilkat.FileAccess
success = fac.OpenForRead("qa_data/xml/hamlet.xml")
' Assuming success for the example..

' We'll upload in 16K blocks (normally a program would upload in larger block sizes than this,
' but this is just an example...)
Dim blockSize As Integer = 16384

' How many 16K blocks?  (Including 1 for the last partial block)
Dim numBlocks As Integer = fac.GetNumBlocks(blockSize)

Dim crypt As New Chilkat.Crypt2
crypt.HashAlgorithm = "md5"

Dim sbResponseBody As New Chilkat.StringBuilder
Dim uriPath As New Chilkat.StringBuilder
Dim blockId As String
Dim dataBlock As New Chilkat.BinData
Dim contentMd5 As String
Dim i As Integer = 0
While i < numBlocks

    dataBlock.Clear()
    success = fac.ReadBlockBd(i,blockSize,dataBlock)
    If (success = False) Then
        Debug.WriteLine(fac.LastErrorText)
        Exit Sub
    End If


    ' Generate a base64 block ID.  
    ' (Chilkat provides a helper method named GenBlockId to make this easy)
    ' A pre-base64 encoded block ID length of 4 is sufficient in this case because
    ' this file certainly won't have more than 99,999 blocks..
    blockId = fac.GenBlockId(i,4,"base64")

    ' Add this blockId to the list of blocks to be committed.
    xml.NewChild2("Latest",blockId)

    ' Build the URI path
    uriPath.Clear()
    success = uriPath.Append("/mycontainer/hamlet.xml?comp=block&blockId=")
    success = uriPath.Append(blockId)

    contentMd5 = crypt.HashBdENC(dataBlock)
    rest.AddHeader("Content-MD5",contentMd5)

    ' Upload this block..
    sbResponseBody.Clear()
    success = rest.FullRequestBd("PUT",uriPath.GetAsString(),dataBlock,sbResponseBody)
    If (success = False) Then
        Debug.WriteLine(rest.LastErrorText)
        Exit Sub
    End If


    ' Verify that we received a 201 status code.
    If (rest.ResponseStatusCode <> 201) Then
        ' Examine the request/response to see what happened.
        Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
        Debug.WriteLine("response status text = " & rest.ResponseStatusText)
        Debug.WriteLine("response header: " & rest.ResponseHeader)
        Debug.WriteLine("response body (if any): " & sbResponseBody.GetAsString())
        Debug.WriteLine("---")
        Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
        Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
        Exit Sub
    End If


    i = i + 1
End While

fac.FileClose()

' Now commit the blocks.
' Let's have a look at the XML that will commit the blocks:
Dim xmlStr As String = xml.GetXml()
Debug.WriteLine(xmlStr)

' The XML will look like this:

' <?xml version="1.0" encoding="utf-8" ?>
' <BlockList>
'     <Latest>MDAwMA==</Latest>
'     <Latest>MDAwMQ==</Latest>
'     <Latest>MDAwMg==</Latest>
'     <Latest>MDAwMw==</Latest>
'     <Latest>MDAwNA==</Latest>
'     <Latest>MDAwNQ==</Latest>
'     <Latest>MDAwNg==</Latest>
'     <Latest>MDAwNw==</Latest>
'     <Latest>MDAwOA==</Latest>
'     <Latest>MDAwOQ==</Latest>
'     <Latest>MDAxMA==</Latest>
'     <Latest>MDAxMQ==</Latest>
'     <Latest>MDAxMg==</Latest>
'     <Latest>MDAxMw==</Latest>
'     <Latest>MDAxNA==</Latest>
'     <Latest>MDAxNQ==</Latest>
'     <Latest>MDAxNg==</Latest>
'     <Latest>MDAxNw==</Latest>
' </BlockList>


' --------------------------------------------------------------------------
' IMPORTANT: Remove the Content-MD5 header previously set in the loop above.
' --------------------------------------------------------------------------
rest.RemoveHeader("Content-MD5")

' Send the PUT Block List...
Dim responseStr As String = rest.FullRequestString("PUT","/mycontainer/hamlet.xml?comp=blocklist",xmlStr)
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, the Azure Storage service will respond with a 201 response status code,
' with no response body.

If (rest.ResponseStatusCode <> 201) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body (if any): " & responseStr)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    Exit Sub
End If


Debug.WriteLine("Success.")