VB.NET Requires Chilkat v11.0.0+

Azure Key Vault Sign with a Certificate's Private Key

See more Azure Key Vault Examples

Signs a hash using the private key of a certificate previously imported to an Azure Key Vault. VB.NET

Dim success As Boolean = False

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  See Azure Key Vault Get Certificates for a more detailed explanation
'  for how Chilkat is automatically getting the OAuth2 access token for your application.

'  Provide information needed for Chilkat to automatically get an OAuth2 access token as needed.
Dim json As New Chilkat.JsonObject
json.UpdateString("client_id","APP_ID")
json.UpdateString("client_secret","APP_PASSWORD")
json.UpdateString("resource","https://vault.azure.net")
json.UpdateString("token_endpoint","https://login.microsoftonline.com/TENANT_ID/oauth2/token")

'  In this example, we'll sign the SHA256 hash of the string "This is a test"
Dim sb As New Chilkat.StringBuilder
Dim signedString As String = "This is a test"
sb.Append(signedString)
Dim hash_base64url As String = sb.GetHash("sha256","base64url","utf-8")

'  We're going to send a POST to the following URL:
'  POST {vaultBaseUrl}/keys/{key-or-cert-name}/{key-or-cert-version}/sign?api-version=7.4

'  For example:

'  POST https://VAULT_NAME.vault.azure.net/keys/CERT_NAME/CERT_VERSION/sign?api-version=7.4
'  
'  {
'    "alg": "RS512",
'    "value": "RUE3Nzg4NTQ4QjQ5RjFFN0U2NzAyQzhDNEMwMkJDOTA1MTYyOTUzNjI5NDhBNzZDQTlFOTM1NDA2M0ZGMjk2Mg"
'  }

'  The alg can be one of the following
'  ES256  ECDSA using P-256 and SHA-256
'  ES256K ECDSA using P-256K and SHA-256
'  ES384  ECDSA using P-384 and SHA-384
'  ES512  ECDSA using P-521 and SHA-512
'  PS256  RSASSA-PSS using SHA-256 and MGF1 with SHA-256
'  PS384  RSASSA-PSS using SHA-384 and MGF1 with SHA-384
'  PS512  RSASSA-PSS using SHA-512 and MGF1 with SHA-512
'  RS256  RSASSA-PKCS1-v1_5 using SHA-256
'  RS384  RSASSA-PKCS1-v1_5 using SHA-384
'  RS512  RSASSA-PKCS1-v1_5 using SHA-512

'  The sample POST above uses SHA512.  We'll instead sign a SHA256 hash..

Dim jsonBody As New Chilkat.JsonObject
jsonBody.UpdateString("alg","RS256")
jsonBody.UpdateString("value",hash_base64url)

Dim http As New Chilkat.Http

'  Instead of providing an actual access token, we give Chilkat the information that allows it to 
'  automatically fetch the access token using the OAuth2 client credentials flow.
http.AuthToken = json.Emit()

http.SetUrlVar("certName","importCert01")
http.SetUrlVar("certVersion","7140c8755ed14839b5d86a9f7e7f0497")
'  Note: Replace "VAULT_NAME" with the name of your Azure key vault.
Dim url As String = "https://VAULT_NAME.vault.azure.net/keys/{$certName}/{$certVersion}/sign?api-version=7.4"
Dim resp As New Chilkat.HttpResponse
success = http.HttpJson("POST",url,jsonBody,"application/json",resp)
If (success = False) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


Dim statusCode As Integer = resp.StatusCode

Dim jsonResp As New Chilkat.JsonObject
resp.GetBodyJson(jsonResp)

jsonResp.EmitCompact = False
Debug.WriteLine(jsonResp.Emit())

If (statusCode <> 200) Then
    Debug.WriteLine("Failed.")
    Exit Sub
End If


'  A successful response body contains JSON like this:
'  Note: Azure's documentation is not very clear, but base64url is the encoding, not "base64".
'  {
'    "kid": "https://kvchilkat.vault.azure.net/keys/importCert01/7140c8755ed14839b5d86a9f7e7f0497",
'    "value": "JzWd2YF21gjtW ... Em37hKOQ"
'  }

'  Let's validate the signature using the cert's public key.
'  This example will load the corresponding certificate from a local file and will verify the signature against the original data.
'  
Dim cert As New Chilkat.Cert
success = cert.LoadFromFile("qa_data/certs/chilkat_code_signing_2024.cer")
If (success = False) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


Dim rsa As New Chilkat.Rsa
'  Tell the RSA object to use the cert's public key.
success = rsa.SetX509Cert(cert,False)
If (success = False) Then
    Debug.WriteLine(rsa.LastErrorText)
    Exit Sub
End If


'  Verify the signature using the cert's public key against the original string.
rsa.EncodingMode = "base64url"
Dim valid As Boolean = rsa.VerifyStringENC(signedString,"sha-256",jsonResp.StringOf("value"))
Debug.WriteLine("signature valid = " & valid)