VB.NET

Azure Blob Service - List all Containers in a Storage Account

See more Azure Cloud Storage Examples

Azure Storage Blob Service REST API: Lists all the containers in a storage account. VB.NET

Dim success As Boolean = False

' Azure Blob Service Example: List all of the containers in an account.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

' Connect to the Azure Storage Blob Service
Dim bTls As Boolean = True
Dim port As Integer = 443
Dim bAutoReconnect As Boolean = True
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Provide Azure Cloud credentials for the REST call.
Dim azAuth As New Chilkat.AuthAzureStorage
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' URI parameters, such as "maxresults", are added by calling AddQueryParam
success = rest.AddQueryParam("maxresults","1000")

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization.  These headers
' are automatically set by Chilkat.

Dim responseStr As String = rest.FullRequestNoBody("GET","/?comp=list")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, the Azure Storage service will respond with a 200 response code,
' with an XML body.  
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body (if any): " & responseStr)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    Exit Sub
End If


' Load the XML response for parsing.
' A sample XML response containing 2 containers is shown below.
Dim xml As New Chilkat.Xml
success = xml.LoadXml(responseStr)

Debug.WriteLine(xml.GetXml())

' Iterate over the containers, listing some information about each.
success = xml.FindChild2("Containers")
Dim numContainers As Integer = xml.NumChildren
Dim i As Integer = 0
While (i < numContainers)
    success = xml.GetChild2(i)
    Debug.WriteLine("Container Name: " & xml.GetChildContent("Name"))
    Dim lastModDateStr As String = xml.ChilkatPath("Properties|Last-Modified|*")
    Debug.WriteLine("Last Modified: " & lastModDateStr)
    ' The date/time string can be loaded into a CkDateTime object for conversion to other date formats..
    Dim dateTime As New Chilkat.CkDateTime
    success = dateTime.SetFromRfc822(lastModDateStr)

    Dim leaseState As String = xml.ChilkatPath("Properties|LeaseState|*")
    Debug.WriteLine("Lease State: " & leaseState)

    success = xml.GetParent2()
    i = i + 1
End While
success = xml.GetParent2()

' Sample XML response:

' 	<?xml version="1.0" encoding="utf-8" ?>
' 	<EnumerationResults ServiceEndpoint="https://chilkat.blob.core.windows.net/">
' 	    <MaxResults>1000</MaxResults>
' 	    <Containers>
' 	        <Container>
' 	            <Name>test</Name>
' 	            <Properties>
' 	                <Last-Modified>Wed, 20 Apr 2016 01:02:25 GMT</Last-Modified>
' 	                <Etag>"0x8D368B77024C583"</Etag>
' 	                <LeaseStatus>unlocked</LeaseStatus>
' 	                <LeaseState>available</LeaseState>
' 	            </Properties>
' 	        </Container>
' 	        <Container>
' 	            <Name>test2</Name>
' 	            <Properties>
' 	                <Last-Modified>Tue, 03 May 2016 17:13:01 GMT</Last-Modified>
' 	                <Etag>"0x8D373762EB6AC85"</Etag>
' 	                <LeaseStatus>unlocked</LeaseStatus>
' 	                <LeaseState>available</LeaseState>
' 	            </Properties>
' 	        </Container>
' 	    </Containers>
' 	    <NextMarker />
' 	</EnumerationResults>