VB.NET Requires Chilkat v11.0.0+

Get ETK Public Key (api-acpt.ehealth.fgov.be)

See more Belgian eHealth Platform Examples

The following URL returns JSON, which contains a PKCS7 signed data:

https://api-acpt.ehealth.fgov.be/etee/v1/etks?identifier=12345678901&type=SSIN

This example extracts the signed data, validates it, and then extracts the public key from the certificate (obtained from signed content in the PKCS7)

Note: The URL above uses "12345678901" which is not valid. You should replace it with a valid number.

VB.NET

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

Dim jsonStr As String = http.QuickGetStr("https://api-acpt.ehealth.fgov.be/etee/v1/etks?identifier=12345678901&type=SSIN")
If (http.LastMethodSuccess = False) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


Debug.WriteLine(jsonStr)

'  The JSON contains something like this:

'  [
'      {
'          "key": {
'              "applicationIdentifier": "",
'              "ssin": "12345678901"
'          },
'          "value": "MIAGCSq....AAAAAAAA=="
'      }
'  ]

'  Note: The above is a JSON array (not a JSON object)
'  It should be loaded into a Chilkat JSON array.
Dim jarr As New Chilkat.JsonArray
success = jarr.Load(jsonStr)
If (success = False) Then
    Debug.WriteLine("Failed to load JSON.")
    Exit Sub
End If


Dim json As Chilkat.JsonObject = jarr.ObjectAt(0)
Dim bdPkcs7 As New Chilkat.BinData
bdPkcs7.AppendEncoded(json.StringOf("value"),"base64")


'  Let's verify the PKCS7, and then examine the signing cert,
'  and get the signing cert's public key.
Dim crypt As New Chilkat.Crypt2

'  Validate the signedData PKCS7, and replace the contents of bdPkcs7 with the extracted signed content.
success = crypt.OpaqueVerifyBd(bdPkcs7)
If (success = False) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


'  The signed content is the DER of a certificate.
'  In other words, bdPkcs7 now contains a certificate.
Dim cert As New Chilkat.Cert
success = cert.LoadFromBd(bdPkcs7)
If (success = False) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


'  Show some certificate information:
Debug.WriteLine("Subject: " & cert.SubjectDN)
Debug.WriteLine("Serial: " & cert.SerialNumber)
Debug.WriteLine("Issuer: " & cert.IssuerDN)

'  Let's get the cert's public key...
Dim pubKey As New Chilkat.PublicKey
cert.GetPublicKey(pubKey)

'  OK, you now have the public key and can do whatever is needed..
Debug.WriteLine(pubKey.KeyType)
Debug.WriteLine(pubKey.KeySize)