(VB.NET) ABN AMRO Create Signed JSON Web Token

Demonstrates how to create a signed JWT to be used for authenticating requests to the ABN AMRO REST API's.

For more information, see https://developer.abnamro.com/get-started#headingFive

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.


' Create public/private key pair (RSA)
Dim rsa As New Chilkat.Rsa

' Generate a 2048-bit key.
Dim success As Boolean = rsa.GenerateKey(2048)
If (success <> True) Then
    Debug.WriteLine(rsa.LastErrorText)
    Exit Sub
End If


' Export the key to PEM files.
' Write one PEM file for the private key, and one for the public key.
Dim privkey As Chilkat.PrivateKey = rsa.ExportPrivateKeyObj()
success = privkey.SavePemFile("qa_data/pem/abnAmroPrivateKey.pem")

Dim pubkey As Chilkat.PublicKey = rsa.ExportPublicKeyObj()
success = pubkey.SavePemFile(True,"qa_data/pem/abnAmroPublicKey.pem")
' Note: Please share your public key along with your app name and developer email id at api.support@nl.abnamro.com. 
' Token generation will not work unless public key is associated with your app.

' Create the JWT.
Dim jwt As New Chilkat.Jwt

' Create the header:
' {
'     "typ": "JWT",
'     "alg": "RS256"
' }
Dim jsonHeader As New Chilkat.JsonObject
jsonHeader.UpdateString("typ","JWT")
jsonHeader.UpdateString("alg","RS256")

' Create the payload:
' {
'     "nbf": 1499947668,
'     "exp": 1499948668,
'     "iss": "me",
'     "sub": "anApiKey",
'     "aud": "https://auth-sandbox.abnamro.com/oauth/token"
' }
Dim jsonPayload As New Chilkat.JsonObject

Dim curDateTime As Integer = jwt.GenNumericDate(0)

' Set the "not process before" timestamp to now.
success = jsonPayload.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = jsonPayload.AddIntAt(-1,"exp",curDateTime + 3600)

jsonPayload.UpdateString("iss","me")
jsonPayload.UpdateString("sub","anApiKey")
jsonPayload.UpdateString("aud","https://auth-sandbox.abnamro.com/oauth/token")

' Produce the smallest possible JWT:
jwt.AutoCompact = True

Dim jwtStr As String = jwt.CreateJwtPk(jsonHeader.Emit(),jsonPayload.Emit(),privkey)
If (jwt.LastMethodSuccess <> True) Then
    Debug.WriteLine(jwt.LastErrorText)
    Exit Sub
End If





' Here is the JWT:
Debug.WriteLine(jwtStr)