(VB.NET) Aadhaar Paperless Offline e-kyc

Opens an encrypted .zip containing Aadhaar Paperless Offline e-KYC XML. Gets the XML and validates the digital signature. Then computes the hash for the mobile number and Email ID.

For more information, see https://uidai.gov.in/ecosystem/authentication-devices-documents/about-aadhaar-paperless-offline-e-kyc.html

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.


' Open the .zip containing the Aadhaar Paperless Offline e-KYC XML.
' The .zip is encrypted using the "Share Phrase".
Dim zip As New Chilkat.Zip
Dim success As Boolean = zip.OpenZip("qa_data/xml_dsig/offline_paperless_kyc.zip")
If (success = False) Then
    Debug.WriteLine(zip.LastErrorText)
    Exit Sub
End If


' The .zip should contain 1 XML file.
Dim entry As Chilkat.ZipEntry = zip.GetEntryByIndex(0)
If (zip.LastMethodSuccess = False) Then
    Debug.WriteLine(zip.LastErrorText)
    Exit Sub
End If


' To get the contents, we need to specify the Share Phrase.
Dim sharePhrase As String = "Lock@487"
zip.DecryptPassword = sharePhrase

Dim bdXml As New Chilkat.BinData
' The XML file will be unzipped into the bdXml object.
success = entry.UnzipToBd(bdXml)
If (success = False) Then
    Debug.WriteLine(entry.LastErrorText)

    Exit Sub
End If




' First verify the XML digital signature.
Dim dsig As New Chilkat.XmlDSig
success = dsig.LoadSignatureBd(bdXml)
If (success <> True) Then
    Debug.WriteLine(dsig.LastErrorText)
    Exit Sub
End If


' The UIDAI XML signature does not contain the KeyInfo, so we must load the uidai certificate
' and indicate that its public key is to be used for verifying the signature.
Dim cert As New Chilkat.Cert
success = cert.LoadFromFile("qa_data/xml_dsig/uidai_auth_sign_prod_2023.cer")
If (success <> True) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


' Get the certificate's public key.
Dim pubKey As Chilkat.PublicKey = cert.ExportPublicKey()
success = dsig.SetPublicKey(pubKey)


' The XML in this example contains only 1 signature.
Dim bVerifyReferenceDigests As Boolean = True
Dim bVerified As Boolean = dsig.VerifySignature(bVerifyReferenceDigests)
If (bVerified = False) Then
    Debug.WriteLine(dsig.LastErrorText)
    Debug.WriteLine("The signature was not valid.")
    Exit Sub
End If


Debug.WriteLine("The XML digital signature is valid.")

' Let's compute the hash for the Mobile Number.

' 	Hashing logic for Mobile Number :
' 	Sha256(Sha256(Mobile+SharePhrase))*number of times last digit of Aadhaar number
' 	(Ref ID field contains last 4 digits).
' 
' 	Example :
' 	Mobile: 1234567890
' 	Aadhaar Number:XXXX XXXX 3632
' 	Passcode : Lock@487
' 	Hash: Sha256(Sha256(1234567890Lock@487))*2
' 	In case of Aadhaar number ends with Zero we will hashed one time.


Dim crypt As New Chilkat.Crypt2
crypt.HashAlgorithm = "sha256"
crypt.EncodingMode = "hexlower"

Dim strToHash As String = "1234567890Lock@487"
Dim bdHash As New Chilkat.BinData
success = bdHash.AppendString(strToHash,"utf-8")

' Hash a number of times equal to the last digit of your Aadhaar number.
' If the Aadhaar number ends with 0, then hash one time.
' For this example, we'll just set the number of times to hash
' for the case where an Aadhaar number ends in "9"
Dim numTimesToHash As Integer = 9
Dim i As Integer
For i = 1 To numTimesToHash
    Dim tmpStr As String = crypt.HashBdENC(bdHash)
    bdHash.Clear()
    bdHash.AppendString(tmpStr,"utf-8")
Next

Debug.WriteLine("Computed Mobile hash = " & bdHash.GetString("utf-8"))

' Let's get the mobile hash stored in the XML and compare it with our computed hash.
Dim xml As New Chilkat.Xml
success = xml.LoadBd(bdXml,True)
Dim m_hash As String = xml.ChilkatPath("UidData|Poi|(m)")

Debug.WriteLine("Stored Mobile hash   = " & m_hash)


' Now do the same thing for the email hash:

strToHash = "abc@gm.comLock@487"
bdHash.Clear()
success = bdHash.AppendString(strToHash,"utf-8")

For i = 1 To numTimesToHash
    Dim tmpStr As String = crypt.HashBdENC(bdHash)
    bdHash.Clear()
    bdHash.AppendString(tmpStr,"utf-8")
Next

Debug.WriteLine("Computed Email hash = " & bdHash.GetString("utf-8"))

Dim e_hash As String = xml.ChilkatPath("UidData|Poi|(e)")
Debug.WriteLine("Stored Email hash   = " & e_hash)