(Visual Basic 6.0) Set Entry Filepath (in output Zip) when Zipping

Demonstrates how to set the path for the file entry within the .zip to something different than the path in the filesystem.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat Zip API to have been previously unlocked.
' See Unlock Chilkat Zip for sample code.

Dim zip As New ChilkatZip

Dim success As Long
success = zip.NewZip("qa_output/zipA.zip")

' When an absolute filepath is passed to AppendOneFileOrDir, the path within the .zip
' will be one of two values:  (1) just the filename part if saveExtraPath is 0,
' or (2) the full absolute path, but made relative, if saveExtraPath is 1.
' (For example, "c:/ck2000/appData/UnitTest/qa_data/hamlet.xml" made relative is 
' "ck2000/appData/UnitTest/qa_data/hamlet.xml")
Dim saveExtraPath As Long
saveExtraPath = 0
success = zip.AppendOneFileOrDir("c:/ck2000/appData/UnitTest/qa_data/hamlet.xml",saveExtraPath)
If (success <> 1) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

' When a relative path is passed to AppendOneFileOrDir, then saveExtraPath does not apply.
' For example, assume our current working directory is "c:/ck2000/appData/UnitTest".  The following
' call to AppendOneFileOrDir creates an entry with the filepath "qa_data/hamlet.xml".
success = zip.AppendOneFileOrDir("qa_data/hamlet.xml",saveExtraPath)
If (success <> 1) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

' Examine the entries
Dim numEntries As Long
numEntries = zip.NumEntries
Dim i As Long
i = 0
Do While i < numEntries
    Dim e As ChilkatZipEntry
    Set e = zip.GetEntryByIndex(i)
    Debug.Print i & ": " & e.FileName

    i = i + 1
Loop

' The output so far is:

' 	0: hamlet.xml
' 	1: qa_data/hamlet.xml

' If we write the .zip as-is, then the zip will have two entries
' with the filepaths as shown above.

' This writes "qa_output/zipA.zip"
success = zip.WriteZip()

' Now change the entry filepaths to whatever is desired.
Dim entry As ChilkatZipEntry
Set entry = zip.GetEntryByName("hamlet.xml")
If (zip.LastMethodSuccess = 0) Then
    Debug.Print "entry not found"
    Exit Sub
End If

entry.FileName = "Shakespeare/Claudius1.xml"

Set entry = zip.GetEntryByName("qa_data/hamlet.xml")
If (zip.LastMethodSuccess = 0) Then
    Debug.Print "entry not found"
    Exit Sub
End If

entry.FileName = "Shakespeare/Claudius2.xml"

' Change the name of the .zip to be written and write again:
zip.FileName = "qa_output/zipB.zip"
success = zip.WriteZipAndClose()
If (success <> 1) Then
    Debug.Print zip.LastErrorText
Else
    Debug.Print "Zip created!"
End If

' Examine both zipA.zip and zipB.zip using 7zip (or another tool) to see the differences.