(Visual Basic 6.0) Create/Verify XML Signature with External Text Reference

See more XML Digital Signatures Examples

Demonstrates how to create an XML digital signature where the referenced data is external. In this case, the data is a text file located at the following URL: https://www.chilkatsoft.com/helloWorld.txt

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example inserts an XML signature into the following XML:

' <?xml version="1.0" encoding="UTF-8" standalone="no"?>
' <abc>
'   <xyz>
' 	<name>helloWorld.txt</name>
' 	<url>https://www.chilkatsoft.com/helloWorld.txt</url>
'   </xyz>
' </abc>

' Build the above XML to be signed.
Dim xml As New ChilkatXml
xml.Tag = "abc"
xml.UpdateChildContent "xyz|name","helloWorld.txt"
xml.UpdateChildContent "xyz|url","https://www.chilkatsoft.com/helloWorld.txt"

Dim cert As New ChilkatCert

Dim success As Long
success = cert.LoadPfxFile("qa_data/pfx/test_secret.pfx","secret")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

Dim gen As New ChilkatXmlDSigGen

' Indicate the location within the XML the Signature will be inserted.
gen.SigLocation = "abc|xyz"

' Get the content of the text data to be referenced.
Dim http As New ChilkatHttp
Dim sbExternalTxt As New ChilkatStringBuilder
success = http.QuickGetSb("https://www.chilkatsoft.com/helloWorld.txt",sbExternalTxt)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

success = gen.AddExternalTextRef("https://www.chilkatsoft.com/helloWorld.txt",sbExternalTxt,"utf-8",0,"sha256","")
If (success = 0) Then
    Debug.Print gen.LastErrorText
    Exit Sub
End If

' Provide the private key for signing via the certificate, and indicate that
' we want the base64 of the certificate embedded in the KeyInfo.
gen.KeyInfoType = "X509Data"
gen.X509Type = "Certificate"

Dim bUsePrivateKey As Long
bUsePrivateKey = 1
success = gen.SetX509Cert(cert,bUsePrivateKey)
If (success <> 1) Then
    Debug.Print gen.LastErrorText
    Exit Sub
End If

' Indicate we want an indented signature for readability.
' This can be removed after debugging is finished..
gen.Behaviors = "IndentedSignature"

' Now create and insert the Signature
Dim sbXml As New ChilkatStringBuilder
success = xml.GetXmlSb(sbXml)
success = gen.CreateXmlDSigSb(sbXml)
If (success <> 1) Then
    Debug.Print gen.LastErrorText
    Exit Sub
End If

' Examine the XML with the digital signature inserted
Debug.Print sbXml.GetAsString()

' Here is the output:

' <?xml version="1.0" encoding="utf-8"?>
' <abc>
'     <xyz>
'         <name>helloWorld.txt</name>
'         <url>https://www.chilkatsoft.com/helloWorld.txt</url>
'     <ds:Signature xmlns:ds="http://www.w3.org/2000/09/xmldsig#">
'   <ds:SignedInfo>
'     <ds:CanonicalizationMethod Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/>
'     <ds:SignatureMethod Algorithm="http://www.w3.org/2001/04/xmldsig-more#rsa-sha256"/>
'     <ds:Reference URI="https://www.chilkatsoft.com/helloWorld.txt">
'       <ds:DigestMethod Algorithm="http://www.w3.org/2001/04/xmlenc#sha256"/>
'       <ds:DigestValue>f4OxZX/x/FO5LcGBSKHWXfwtSx+j1ncoSt3SABJtkGk=</ds:DigestValue>
'     </ds:Reference>
'   </ds:SignedInfo>
'   <ds:SignatureValue>syFSl...pZDiFQ==</ds:SignatureValue>
'   <ds:KeyInfo>
'     <ds:X509Data>
'       <ds:X509Certificate>MIIHAz...GwnUZWCaDE=</ds:X509Certificate>
'     </ds:X509Data>
'   </ds:KeyInfo>
' </ds:Signature></xyz>
' </abc>

' Let's verify the signature...
Dim verifier As New ChilkatXmlDSig
success = verifier.LoadSignatureSb(sbXml)
If (success <> 1) Then
    Debug.Print verifier.LastErrorText
    Exit Sub
End If

' Let's examine the external references, and fetch the data for each..
Dim sbExternalData As New ChilkatStringBuilder
Dim numRefs As Long
numRefs = verifier.NumReferences
Dim i As Long
i = 0
Do While i < numRefs
    Dim bExternal As Long
    bExternal = verifier.IsReferenceExternal(i)
    If (bExternal = 1) Then
        Dim uri As String
        uri = verifier.ReferenceUri(i)

        ' We're assuming the URI is an https:// or http:// URL...
        ' Let's also assume we know that the referenced data is text and we want the utf-8 byte representation.
        sbExternalData.Clear 
        success = http.QuickGetSb(uri,sbExternalData)
        If (success = 0) Then
            Debug.Print http.LastErrorText
            Exit Sub
        End If

        success = verifier.SetRefDataSb(i,sbExternalData,"utf-8")
        If (success = 0) Then
            Debug.Print verifier.LastErrorText
            Exit Sub
        End If

    End If

    i = i + 1
Loop

' Now that we have the external data available, we can verify the reference digest(s) and the signature.
Dim bVerified As Long
bVerified = verifier.VerifySignature(1)
If (bVerified <> 1) Then
    Debug.Print verifier.LastErrorText
    Exit Sub
End If

Debug.Print "Signature verified!"