(Visual Basic 6.0) Traverse Direct Children via FirstChild / NextSibling, or LastChild / PreviousSibling

Demonstrates some ways to iterate over direct child nodes using the FirstChild / NextSibling and LastChild / PreviousSibling methods.

The input XML, available at http://www.chilkatsoft.com/data/fruit.xml, is this:

<root>
    <fruit color="red">apple</fruit>
    <fruit color="green">pear</fruit>
    <veg color="orange">carrot</veg>
    <meat animal="cow">beef</meat>
    <xyz>
        <fruit color="blue">blueberry</fruit>
        <veg color="green">broccoli</veg>
    </xyz>
    <fruit color="purple">grape</fruit>
    <cheese color="yellow">cheddar</cheese>
</root>

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim xml As New ChilkatXml
Dim child As ChilkatXml
Dim nextSibling As ChilkatXml
Dim prevSibling As ChilkatXml

Dim success As Long
success = xml.LoadXmlFile("qa_data/xml/fruit.xml")
If (success <> 1) Then
    Debug.Print xml.LastErrorText
    Exit Sub
End If

' Iterate over the direct children by using FirstChild / NextSibling
Set child = xml.FirstChild()
Dim bContinue As Long
bContinue = xml.LastMethodSuccess
Do While (bContinue = 1)
    Debug.Print child.Tag & " : " & child.Content
    Set nextSibling = child.NextSibling()
    bContinue = child.LastMethodSuccess

    Set child = nextSibling
Loop
Debug.Print "-----"

' Do the same, but with FirstChild2 / NextSibling2 to avoid
' creating so many XML object instances:
success = xml.FirstChild2()
Do While success = 1
    Debug.Print xml.Tag & " : " & xml.Content
    success = xml.NextSibling2()
Loop
' Revert back up to the parent:
success = xml.GetParent2()

Debug.Print "-----"

' Iterate in reverse order using LastChild / PreviousSibling
Set child = xml.LastChild()
bContinue = xml.LastMethodSuccess
Do While (bContinue = 1)
    Debug.Print child.Tag & " : " & child.Content
    Set prevSibling = child.PreviousSibling()
    bContinue = child.LastMethodSuccess

    Set child = prevSibling
Loop
Debug.Print "-----"

' Do the same, but with LastChild2 / PreviousSibling2 to avoid
' creating so many XML object instances:
success = xml.LastChild2()
Do While success = 1
    Debug.Print xml.Tag & " : " & xml.Content
    success = xml.PreviousSibling2()
Loop
' Revert back up to the parent:
success = xml.GetParent2()