(Visual Basic 6.0) Xero Upload Attachment

Demonstrates how to upload an attachment to Xero.

For more information, see https://developer.xero.com/documentation/api/attachments#POST

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' Important: Make sure your OAuth2 access token was obtained with the scope "accounting.attachments"
' included in the list of scopes.

Dim jsonToken As New ChilkatJsonObject
Dim success As Long
success = jsonToken.LoadFile("qa_data/tokens/xero-access-token.json")
If (success = 0) Then
    Debug.Print jsonToken.LastErrorText
    Exit Sub
End If

http.AuthToken = jsonToken.StringOf("access_token")

' Replace the value here with an actual tenant ID obtained from this example:
' Get Xero Tenant IDs
http.SetRequestHeader "Xero-tenant-id","83299b9e-5747-4a14-a18a-a6c94f824eb7"

http.Accept = "application/json"

Dim url As String
url = "https://api.xero.com/api.xro/2.0/{$Endpoint}/{$Guid}/Attachments/{$Filename}"

' Endpoint can be Invoices, Receipts, CreditNotes, PurchaseOrders, etc.
success = http.SetUrlVar("Endpoint","Invoices")

' Guid is the ID of the item, such as the InvoiceID.
success = http.SetUrlVar("Guid","0032f627-3156-4d30-9b1c-4d3b994dc921")

' Filename is the filename of the attachment you are uploading.
success = http.SetUrlVar("Filename","penguins.jpg")

' Load the file to be uploaded (from the local filesystem).
Dim bd As New ChilkatBinData
success = bd.LoadFile("qa_data/jpg/penguins.jpg")
If (success = 0) Then
    Debug.Print "Failed to load attachment file."
    Exit Sub
End If

' Indicate the content-type according to the file content type.
' Common content-types are:   image/jpg, image/png, application/pdf, application/zip, application/msword
' If you don't know, use application/octet-stream
Dim resp As ChilkatHttpResponse
Set resp = http.PBinaryBd("POST",url,bd,"image/jpg",0,0)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "Response Status Code: " & resp.StatusCode

Dim jsonResponse As New ChilkatJsonObject
success = jsonResponse.Load(resp.BodyStr)
jsonResponse.EmitCompact = 0
Debug.Print jsonResponse.Emit()

If (resp.StatusCode <> 200) Then
    Debug.Print "Failed."

    Exit Sub
End If

' A sample response:

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

' {
'   "Id": "35333c64-4449-457b-bf6a-1b64d538e3c7",
'   "Status": "OK",
'   "ProviderName": "Chilkat2222",
'   "DateTimeUTC": "\/Date(1587212597758)\/",
'   "Attachments": [
'     {
'       "AttachmentID": "daf106e2-8634-4349-bfcc-86c1df0793b2",
'       "FileName": "penguins.jpg",
'       "Url": "https://api.xero.com/api.xro/2.0/Invoices/0032f627-3156-4d30-9b1c-4d3b994dc921/Attachments/penguins.jpg",
'       "MimeType": "image/jpg",
'       "ContentLength": 777835
'     }
'   ]
' }