(Visual Basic 6.0) Refresh Wish for Merchants OAuth2 Access Token

Demonstrates how to refresh a Wish OAuth2 access token.

Note: This example requires Chilkat v9.5.0.85.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' See Get Wish OAuth2 Access Token 
' for sample code showing how to obtain a Wish access token for desktop apps.

' This example assumes we previously obtained an OAuth2 access token for Wish.

Dim jsonToken As New ChilkatJsonObject
Dim success As Long
success = jsonToken.LoadFile("qa_data/tokens/wish.json")
If (success <> 1) Then
    Debug.Print "Failed to load wish.json"
    Exit Sub
End If

' The access token JSON looks something like this:

' {
'   "message": "",
'   "code": 0,
'   "data": {
'     "access_token": "15af1c191c1243b029bc1660b5c08ce7",
'     "scopes": [
'       "epc:read",
'       "epc:write",
'       "fbs:read",
'       "fbs:write",
'       "fbw:read",
'       "fbw:write",
'       "infractions:read",
'       "infractions:write",
'       "insurance:read",
'       "insurance:write",
'       "loans:read",
'       "loans:write",
'       "merchant:read",
'       "merchant:write",
'       "notifications:read",
'       "notifications:write",
'       "orders:read",
'       "orders:write",
'       "payments:read",
'       "payments:write",
'       "penalties:read",
'       "penalties:write",
'       "product_boost:read",
'       "product_boost:write",
'       "products:read",
'       "products:write",
'       "ratings:read",
'       "ratings:write",
'       "returns:read",
'       "returns:write",
'       "tickets:read",
'       "tickets:write"
'     ],
'     "merchant_id": "5eb3f605178f5be2c784fa02",
'     "expiry_time": "2020-12-17T16:55:09.594+00:00",
'     "refresh_token": "55a38e44df674a1e859891624b2c4c23"
'   }
' }

Dim oauth2 As New ChilkatOAuth2

' Note: In most OAuth2 implementations, the token endpoint is the same for both the
' refresh request and the exchange-code-for-token request (which happens when getting
' the OAuth2 token for the 1st time).   Wish uses a different URL for the refresh:
oauth2.TokenEndpoint = "https://merchant.wish.com/api/v3/oauth/refresh_token"

' The following uncommon option was added in Chilkat v9.5.0.85
oauth2.UncommonOptions = "EXCHANGE_CODE_FOR_TOKEN_USING_GET"

' Replace these with actual values.
oauth2.ClientId = "WISH-CLIENT-ID"
oauth2.ClientSecret = "WISH-CLIENT-SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("data.refresh_token")

' Send the HTTP request to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Save the new JSON access token response to a file.
' The access + refresh tokens contained in this JSON will be needed for the next refresh.
Dim sbJson As New ChilkatStringBuilder
success = sbJson.Append(oauth2.AccessTokenResponse)
success = sbJson.WriteFile("qa_data/tokens/wish.json","utf-8",0)

Debug.Print "OAuth2 token refreshed!"
Debug.Print "New Access Token = " & oauth2.AccessToken