Visual Basic 6.0

Duplicate Python websockets

See more WebSocket Examples

Demonstrates how to duplicate the following Python client-side websocket snippet:

async with websockets.connect('ws://192.168.1.35/websocket') as websocket:
await websocket.send("http.controller_login:username=xxx&password=xxxxx")
response = await websocket.recv()

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' In Python, the following line of code does more than just connect:
' 
'      websockets.connect('ws://192.168.1.35/websocket')
' 
' It is connecting to 192.168.1.35 without using TLS.  If the URI starts with "wss://", then TLS should be used.
' But this URI begins with just "ws:/", so no TLS.

' Also, after connecting, a GET request is sent to the /websocket endpoint.
' In summary, the websockets.connect function is establishing the connection and it sends a GET request.

' First establish the connection.
' No TLS, use the default HTTP port 80.
Dim rest As New ChilkatRest
success = rest.Connect("192.168.1.35",80,0,0)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim ws As New ChilkatWebSocket

' Tell the WebSocket to use this connection.
success = ws.UseConnection(rest)
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Exit Sub
End If

' Add the standard WebSocket open handshake headers that will be needed.
' (This adds the required HTTP request headers to the rest object.)
success = ws.AddClientHeaders()

' Now send the GET request to /websockets.
Dim responseBody As String
responseBody = rest.FullRequestNoBody("GET","/websockets")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' If successful, the HTTP response status code should be 101,
' and the response body will be empty. (If it failed, we'll have a look
' at the response body..)
Dim statusCode As Long
statusCode = rest.ResponseStatusCode
Debug.Print "Response status code: " & statusCode

If (statusCode <> 101) Then
    Debug.Print responseBody
    Debug.Print "-- Failed because of unexpected response status code."
    Exit Sub
End If

' We have the expected 101 response, so let's now validate the 
' contents of the response.
success = ws.ValidateServerHandshake()
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Exit Sub
End If

Debug.Print "WebSocket connection successful."

' The application may now begin sending and receiving frames on the WebSocket connection.

' The 1st frame sent by the Python snippet is:
' 
'     websocket.send("http.controller_login:username=xxx&password=xxxxx")
' 

' Send the same using Chilkat, and get the response.
Dim finalFrame As Long
finalFrame = 1
success = ws.SendFrame("http.controller_login:username=xxx&password=xxxxx",finalFrame)
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Exit Sub
End If

' Read an incoming frame.
success = ws.ReadFrame()
If (success <> 1) Then
    Debug.Print "Failed to receive a frame"
    Debug.Print "ReadFrame fail reason = " & ws.ReadFrameFailReason
    Debug.Print ws.LastErrorText
    Exit Sub
End If

' Show the string that was received.
Dim receivedStr As String
receivedStr = ws.GetFrameData()
Debug.Print "Received: " & receivedStr

' Continue with whatever additional communications are desired...
' ....
'