(Visual Basic 6.0) Binary.com Tick Stream

Tick Stream Request -- Initiate a continuous stream of spot price updates for a given symbol.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim ws As New ChilkatWebSocket

'  For brevity, this example does not check for errors when etablishing the WebSocket connection.
'  See Establish WebSocket Connection for more complete sample code for making the connection.

Dim rest As New ChilkatRest

'  Connect to ws.binaryws.com
Dim success As Long
success = rest.Connect("ws.binaryws.com",443,1,0)
success = ws.UseConnection(rest)
success = ws.AddClientHeaders()

'  My app_id is 12332.  You'll wnat to use your own...
Dim responseBody As String
responseBody = rest.FullRequestNoBody("GET","/websockets/v3?app_id=12332")
success = ws.ValidateServerHandshake()
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Debug.Print responseBody
    Debug.Print rest.ResponseHeader
    Exit Sub
End If

'  Build and send the following message:

'  {
'    "ticks": "R_50",
'    "subscribe": 1
'  }

Dim json As New ChilkatJsonObject
success = json.AppendString("ticks","R_50")
success = json.AppendInt("subscribe",1)

'  Send a full message in a single frame
Dim finalFrame As Long
finalFrame = 1
success = ws.SendFrame(json.Emit(),finalFrame)
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Exit Sub
End If

Dim jsonTickData As New ChilkatJsonObject
jsonTickData.EmitCompact = 0

'  Begin reading the tick stream response.
'  We'll just read the 1st 10 updates and then exit..
Dim receivedFinalFrame As Long
receivedFinalFrame = 0
Dim numTicksReceived As Long
numTicksReceived = 0
Do While numTicksReceived < 5

    success = ws.ReadFrame()
    If (success <> 1) Then
        Debug.Print "Failed to receive a frame"
        Debug.Print "ReadFrame fail reason = " & ws.ReadFrameFailReason
        Debug.Print ws.LastErrorText
        Exit Sub
    End If

    '  The responses we desire are in Text frames, where the opcode = 1.
    If (ws.FrameOpcodeInt = 1) Then
        Dim receivedJson As String
        receivedJson = ws.GetFrameData()

        success = jsonTickData.Load(receivedJson)
        Debug.Print jsonTickData.Emit()

        numTicksReceived = numTicksReceived + 1
    End If

Loop

'  Close the websocket connection.
success = ws.SendClose(1,1000,"Closing this websocket.")
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Exit Sub
End If

'  Read the Close response.
success = ws.ReadFrame()
If (success <> 1) Then
    Debug.Print "ReadFrame fail reason = " & ws.ReadFrameFailReason
    Debug.Print ws.LastErrorText
    Exit Sub
End If

Debug.Print "Success."

'  The output of the above code is shown here:

'  {
'    "echo_req": {
'      "subscribe": 1,
'      "ticks": "R_50"
'    },
'    "msg_type": "tick",
'    "tick": {
'      "ask": "373.8725",
'      "bid": "373.8325",
'      "epoch": "1517437456",
'      "id": "2d3dedf1-45e2-66a5-d0d3-72bd7f0a6ea9",
'      "quote": "373.8525",
'      "symbol": "R_50"
'    }
'  }
' 
'  {
'    "echo_req": {
'      "subscribe": 1,
'      "ticks": "R_50"
'    },
'    "msg_type": "tick",
'    "tick": {
'      "ask": "373.7952",
'      "bid": "373.7552",
'      "epoch": "1517437458",
'      "id": "2d3dedf1-45e2-66a5-d0d3-72bd7f0a6ea9",
'      "quote": "373.7752",
'      "symbol": "R_50"
'    }
'  }
' 
'  {
'    "echo_req": {
'      "subscribe": 1,
'      "ticks": "R_50"
'    },
'    "msg_type": "tick",
'    "tick": {
'      "ask": "373.8638",
'      "bid": "373.8238",
'      "epoch": "1517437460",
'      "id": "2d3dedf1-45e2-66a5-d0d3-72bd7f0a6ea9",
'      "quote": "373.8438",
'      "symbol": "R_50"
'    }
'  }
' 
'  {
'    "echo_req": {
'      "subscribe": 1,
'      "ticks": "R_50"
'    },
'    "msg_type": "tick",
'    "tick": {
'      "ask": "373.7636",
'      "bid": "373.7236",
'      "epoch": "1517437462",
'      "id": "2d3dedf1-45e2-66a5-d0d3-72bd7f0a6ea9",
'      "quote": "373.7436",
'      "symbol": "R_50"
'    }
'  }
' 
'  {
'    "echo_req": {
'      "subscribe": 1,
'      "ticks": "R_50"
'    },
'    "msg_type": "tick",
'    "tick": {
'      "ask": "373.6870",
'      "bid": "373.6470",
'      "epoch": "1517437464",
'      "id": "2d3dedf1-45e2-66a5-d0d3-72bd7f0a6ea9",
'      "quote": "373.6670",
'      "symbol": "R_50"
'    }
'  }
' 
'  Success.