(Visual Basic 6.0) Walmart Partner API Authentication (Generate a Signature for a Request)

Demonstrates how to generate a signature for a Walmart Partner REST API call.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

Dim consumerId As String
consumerId = "b68d2a72...."
Dim baseUrl As String
baseUrl = "https://marketplace.walmartapis.com/v2/feeds"
' This is your Base64 encoded private key
Dim privateEncodedStr As String
privateEncodedStr = "MIICeAIBADANBgkqhkiG9w0BAQEFAA......"
Dim httpMethod As String
httpMethod = "GET"

' We need a timestamp in decimal string form representing the number of milliseconds since Jan 01 1970 UTC.
Dim dt As New CkDateTime
' Set bLocal = 1 for a timestamp in the local timezone.  Set bLocal = 0 for a UTC timestamp.
Dim bLocal As Long
bLocal = 0
' This gets the timestamp in seconds, not milliseconds.
Dim timeStampVal As Long
timeStampVal = dt.GetAsUnixTime(bLocal)

' Build the string to sign.
Dim sbStringToSign As New ChilkatStringBuilder
success = sbStringToSign.Append(consumerId)
success = sbStringToSign.Append(vbLf)
success = sbStringToSign.Append(baseUrl)
success = sbStringToSign.Append(vbLf)
success = sbStringToSign.Append(httpMethod)
success = sbStringToSign.Append(vbLf)
success = sbStringToSign.AppendInt(timeStampVal)
' We add three zero's so that the timestamp value is in milliseconds.
' We don't care about accuracy down to less than a second.
' All the server cares about is that the request was signed at the current date/time
' within some reasonable margin of error (to account for systems having clocks
' that may be slightly different).
success = sbStringToSign.Append("000" & vbLf)

Dim privKey As New PrivateKey
' Load the private key into a private key object.
' Note: Technically the private key is not PEM because it lacks the header/footer strings
' used for PEM.  However, the LoadPem method will still accept it and load it correctly.
success = privKey.LoadPem(privateEncodedStr)
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim rsa As New ChilkatRsa
success = rsa.ImportPrivateKeyObj(privKey)
If (success <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' We want a base64 signature string.
rsa.EncodingMode = "base64"

Dim signatureString As String
signatureString = rsa.SignStringENC(sbStringToSign.GetAsString(),"SHA256")
If (rsa.LastMethodSuccess <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

Debug.Print "Signature String: " & signatureString