(Visual Basic 6.0) URL Encoding Charset in POST Query Params

Demonstrates how to control the URL encoding charset in POST query params.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' We have the string "MÆRSK".
Dim nameWin1252Encoded As String
nameWin1252Encoded = "M%E6RSK"

' Note: The DecodeAndAppend method is newly added in Chilkat v9.5.0.87
Dim sb As New ChilkatStringBuilder
Dim success As Long
success = sb.DecodeAndAppend(nameWin1252Encoded,"url","windows-1252")

Dim http As New ChilkatHttp

' We're setting the session log filename so we can see the exact request sent.
http.SessionLogFilename = "qa_output/sessionLog.txt"

' First demonstrate a simple application/x-www-form-urlencoded POST

Dim req As New ChilkatHttpRequest

' Set the Charset = "utf-8" to cause URL encoding to use utf-8.
req.Charset = "utf-8"

req.AddParam "name",sb.GetAsString()

Dim resp As ChilkatHttpResponse
Set resp = http.PostUrlEncoded("https://www.chilkatsoft.com/something",req)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' This is the request that is sent:
' Notice that utf-8 is used in the query param (the letter 'Æ' is %C3%A6)

' 	POST /something HTTP/1.1
' 	Host: www.chilkatsoft.com
' 	Content-Type: application/x-www-form-urlencoded
' 	Content-Length: 15
' 
' 	name=M%C3%A6RSK

' ---------------------------------------------------------------
' Switch to windows-1252

req.Charset = "windows-1252"

Set resp = http.PostUrlEncoded("https://www.chilkatsoft.com/something",req)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' This is the request that is sent:
' Notice that windows-1252 is used in the query param (the letter 'Æ' is %E6)

' 	POST /something HTTP/1.1
' 	Host: www.chilkatsoft.com
' 	Content-Type: application/x-www-form-urlencoded
' 	Content-Length: 12
' 
' 	name=M%E6RSK

' ---------------------------------------------------------------
' Let's do the same with SynchronousRequest, switching back to utf-8

req.Path = "/something"
req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

req.Charset = "utf-8"

Set resp = http.SynchronousRequest("www.chilkatsoft.com",443,1,req)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' This is the request that is sent:
' Notice that utf-8 is used in the query param (the letter 'Æ' is %C3%A6)

' 	POST /something HTTP/1.1
' 	Host: www.chilkatsoft.com
' 	Content-Type: application/x-www-form-urlencoded
' 	Content-Length: 15
' 
' 	name=M%C3%A6RSK

' ---------------------------------------------------------------
' Let's do a PostXml where the query params are in the HTTP request start line, 
' and the Content-Type is text/xml where the body of the request is XML.

req.Path = "/something"
req.HttpVerb = "POST"
req.ContentType = "text/xml"
success = req.LoadBodyFromString("<test>123</test>","utf-8")
req.Charset = "utf-8"

' Remember... our request object still contains the query param added in the above call to AddParam.

Set resp = http.SynchronousRequest("www.chilkatsoft.com",443,1,req)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' This is the request that is sent:
' Notice that utf-8 is used in the query param (the letter 'Æ' is %C3%A6)

' 	POST /something?name=M%C3%A6RSK HTTP/1.1
' 	Host: www.chilkatsoft.com
' 	Content-Type: text/xml
' 	Content-Length: 16
' 
' 	<test>123</test>