(Visual Basic 6.0) UPS Tracking API

Demonstrates making a call to the UPS tracking REST API. Parses the tracking response and extracts the base64 signature image to a gif file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

Dim http As New ChilkatHttp

' This is the testing endpoint for the tracking API:
Dim url As String
url = "https://wwwcie.ups.com/rest/Track"

' Send an HTTP request with the following JSON body:

' {
'   "UPSSecurity": {
'     "UsernameToken": {
'       "Username": "Your Username",
'       "Password": "Your Password"
'     },
'     "ServiceAccessToken": {
'       "AccessLicenseNumber": "Your Access License Number"
'     }
'   },
'   "TrackRequest": {
'     "Request": {
'       "RequestOption": "1",
'       "TransactionReference": {
'         "CustomerContext": "Your Test Case Summary Description"
'       }
'     },
'     "InquiryNumber": "YourTrackingNumber"
'   }
' }
' 

' Build the above JSON.
Dim json As New ChilkatJsonObject
success = json.UpdateString("UPSSecurity.UsernameToken.Username","UPS_USERNAME")
success = json.UpdateString("UPSSecurity.UsernameToken.Password","UPS_PASSWORD")
success = json.UpdateString("UPSSecurity.ServiceAccessToken.AccessLicenseNumber","UPS_ACCESS_KEY")
' Request all activity...
success = json.UpdateString("TrackRequest.Request.RequestOption","activity")
success = json.UpdateString("TrackRequest.Request.TransactionReference.CustomerContext","Your Test Case Summary Description")
success = json.UpdateString("TrackRequest.InquiryNumber","1Z12345E0205271688")

Dim sb As New ChilkatStringBuilder
Dim resp As ChilkatHttpResponse
Set resp = http.PostJson3(url,"application/json",json)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "status = " & resp.StatusCode

' A 200 response status indicate success.
If (resp.StatusCode <> 200) Then
    Debug.Print resp.BodyStr
    Debug.Print "Failed."

    Exit Sub
End If

success = json.Load(resp.BodyStr)
json.EmitCompact = 0
Debug.Print json.Emit()

' {
'   "TrackResponse": {
'     "Response": {
'       "ResponseStatus": {
'         "Code": "1",
'         "Description": "Success"
'       },
'       "TransactionReference": {
'         "CustomerContext": "Your Test Case Summary Description"
'       }
'     },
'     "Shipment": {
'       "InquiryNumber": {
'         "Code": "01",
'         "Description": "ShipmentIdentificationNumber",
'         "Value": "1Z12345E0205271688"
'       },
'       "ShipmentType": {
'         "Code": "01",
'         "Description": "Small Package"
'       },
'       "ShipperNumber": "12345E",
'       "Service": {
'         "Code": "002",
'         "Description": "2ND DAY AIR"
'       },
'       "ReferenceNumber": {
'         "Code": "01",
'         "Value": "LINE4AND115"
'       },
'       "PickupDate": "19990608",
'       "Package": {
'         "TrackingNumber": "1Z12345E0205271688",
'         "Activity": [
'           {
'             "ActivityLocation": {
'               "Address": {
'                 "City": "ANYTOWN",
'                 "StateProvinceCode": "GA",
' 
'                 "PostalCode": "30340",
'                 "CountryCode": "US"
'               },
'               "Code": "ML",
'               "Description": "BACK DOOR",
'               "SignedForByName": "JOHN DOE"
'             },
'             "Status": {
'               "Type": "D",
'               "Description": "DELIVERED",
'               "Code": "KM"
'             },
'             "Date": "19990610",
'             "Time": "120000",
'             "Document": {
'               "Type": {
'                 "Code": "01",
'                 "Description": "Signature Image"
'               },
'               "Content": "R0lGODdhoA ... JU9Y8RdHsRKLMVJ4MVDMREAAADs=",
'               "Format": {
'                 "Code": "01",
'                 "Description": "GIF"
'               }
'             }
'           },
'           {
'             "Status": {
'               "Type": "M",
'               "Description": "BILLING INFORMATION RECEIVED. SHIPMENT DATE PENDING.",
'               "Code": "MP"
'             },
'             "Date": "19990608",
'             "Time": "120000"
'           }
'         ],
'         "PackageWeight": {
'           "UnitOfMeasurement": {
'             "Code": "LBS"
'           },
'           "Weight": "5.00"
'         },
'         "ReferenceNumber": [
'           {
'             "Code": "01",
'             "Value": "LINE4AND115"
'           },
'           {
'             "Code": "08",
'             "Value": "LJ67Y5"
'           }
'         ]
'       }
'     },
'     "Disclaimer": "You are using UPS tracking service on customer integration test environment, please switch to UPS production environment once you finish the test. The URL is https://onlinetools.ups.com/webservices/Track"
'   }
' }

' Use the online tool at Generate JSON Parsing Code
' to generate JSON parsing code.

Dim statusCode As String
statusCode = json.StringOf("TrackResponse.Response.ResponseStatus.Code")
Dim statusDescription As String
statusDescription = json.StringOf("TrackResponse.Response.ResponseStatus.Description")
Debug.Print "statusCode: " & statusCode
Debug.Print "statusDescription" & statusDescription
Dim customerContext As String
customerContext = json.StringOf("TrackResponse.Response.TransactionReference.CustomerContext")
Dim inquiryNumberCode As String
inquiryNumberCode = json.StringOf("TrackResponse.Shipment.InquiryNumber.Code")
Dim inquiryNumberDescription As String
inquiryNumberDescription = json.StringOf("TrackResponse.Shipment.InquiryNumber.Description")
Dim inquiryNumberValue As String
inquiryNumberValue = json.StringOf("TrackResponse.Shipment.InquiryNumber.Value")
Dim shipmentTypeCode As String
shipmentTypeCode = json.StringOf("TrackResponse.Shipment.ShipmentType.Code")
Dim shipmentTypeDescription As String
shipmentTypeDescription = json.StringOf("TrackResponse.Shipment.ShipmentType.Description")
Dim shipperNumber As String
shipperNumber = json.StringOf("TrackResponse.Shipment.ShipperNumber")
Dim serviceCode As String
serviceCode = json.StringOf("TrackResponse.Shipment.Service.Code")
Dim serviceDescription As String
serviceDescription = json.StringOf("TrackResponse.Shipment.Service.Description")
Dim referenceNumberCode As String
referenceNumberCode = json.StringOf("TrackResponse.Shipment.ReferenceNumber.Code")
Dim referenceNumberValue As String
referenceNumberValue = json.StringOf("TrackResponse.Shipment.ReferenceNumber.Value")
Dim pickupDate As String
pickupDate = json.StringOf("TrackResponse.Shipment.PickupDate")
Dim trackingNumber As String
trackingNumber = json.StringOf("TrackResponse.Shipment.Package.TrackingNumber")
Dim unitOfMeasurementCode As String
unitOfMeasurementCode = json.StringOf("TrackResponse.Shipment.Package.PackageWeight.UnitOfMeasurement.Code")
Dim weight As String
weight = json.StringOf("TrackResponse.Shipment.Package.PackageWeight.Weight")
Dim disclaimer As String
disclaimer = json.StringOf("TrackResponse.Disclaimer")

Dim i As Long
i = 0
Dim activityCount As Long
activityCount = json.SizeOfArray("TrackResponse.Shipment.Package.Activity")
Debug.Print "activityCount: " & activityCount

Do While i < activityCount
    Debug.Print "-- activity " & i
    json.I = i
    If (json.HasMember("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.Address.City") = 1) Then
        Dim city As String
        city = json.StringOf("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.Address.City")
        Debug.Print "city: " & city
        Dim provinceCode As String
        provinceCode = json.StringOf("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.Address.StateProvinceCode")
        Dim postalCode As String
        postalCode = json.StringOf("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.Address.PostalCode")
        Dim countryCode As String
        countryCode = json.StringOf("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.Address.CountryCode")
    End If

    Dim locationCode As String
    locationCode = json.StringOf("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.Code")
    Dim locationDescription As String
    locationDescription = json.StringOf("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.Description")
    Dim locationSignedForByName As String
    locationSignedForByName = json.StringOf("TrackResponse.Shipment.Package.Activity[i].ActivityLocation.SignedForByName")

    Dim activityStatusType As String
    activityStatusType = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Status.Type")
    Debug.Print "activityStatusType: " & activityStatusType
    Dim activityStatusDescription As String
    activityStatusDescription = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Status.Description")
    Debug.Print "activityStatusDescription: " & activityStatusDescription
    Dim activityStatusCode As String
    activityStatusCode = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Status.Code")
    Debug.Print "activityStatusCode: " & activityStatusCode

    Dim activityDate As String
    activityDate = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Date")
    Dim activityTime As String
    activityTime = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Time")

    If (json.HasMember("TrackResponse.Shipment.Package.Activity[i].Document") = 1) Then
        Dim typeCode As Long
        typeCode = json.IntOf("TrackResponse.Shipment.Package.Activity[i].Document.Type.Code")
        Dim typeDescription As String
        typeDescription = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Document.Type.Description")
        Dim documentContent As String
        documentContent = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Document.Content")
        Dim documentFormatCode As String
        documentFormatCode = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Document.Format.Code")
        ' Format description would be something like "GIF" for a signature image.
        Dim documentFormatDescription As String
        documentFormatDescription = json.StringOf("TrackResponse.Shipment.Package.Activity[i].Document.Format.Description")

        ' 01 - Signature Image
        ' 02 - Delivery Receipt
        ' 03 - Free Astray
        ' 04 - POD
        If (typeCode = 1) Then
            ' We have a signature image.  Get the image data and save to a file.
            Dim sbImagePath As New ChilkatStringBuilder
            success = sbImagePath.Append("qa_output/sig_")
            success = sbImagePath.Append(trackingNumber)
            success = sbImagePath.Append(".")
            success = sbImagePath.Append(documentFormatDescription)
            Dim imageData As New ChilkatBinData
            success = imageData.AppendEncoded(documentContent,"base64")
            ' Write to "qa_output/sig_1Z12345E0205271688.GIF"
            success = imageData.WriteFile(sbImagePath.GetAsString())
        End If

    End If

    i = i + 1
Loop

i = 0
Dim refnumCount As Long
refnumCount = json.SizeOfArray("TrackResponse.Shipment.Package.ReferenceNumber")
Do While i < refnumCount
    json.I = i
    Dim refnumCode As String
    refnumCode = json.StringOf("TrackResponse.Shipment.Package.ReferenceNumber[i].Code")
    Dim refnumValue As String
    refnumValue = json.StringOf("TrackResponse.Shipment.Package.ReferenceNumber[i].Value")
    i = i + 1
Loop

Debug.Print "Success."