Visual Basic 6.0

Twinfield OAuth2 for Desktop App or Script

See more OAuth2 Examples

Demonstrates how to get a Twinfield OAuth2 access token from a desktop application or script. Visual Basic 6.0

Dim success As Long
success = 0

' For more information about the OAuth2, see OAuth 2.0 Authorization Flow

Dim oauth2 As New ChilkatOAuth2

' This should be the port in the localhost callback URL for your app.  
' The callback URL would look like "http://localhost:3017/" if the port number is 3017.
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://login.twinfield.com/auth/authentication/connect/authorize"
oauth2.TokenEndpoint = "https://login.twinfield.com/auth/authentication/connect/token"

' Replace these with actual values.
oauth2.ClientId = "CLIENT_ID"
oauth2.ClientSecret = "CLIENT_SECRET"

oauth2.Scope = "openid twf.user twf.organisation twf.organisationUser offline_access"

oauth2.CodeChallenge = 1
oauth2.CodeChallengeMethod = "S256"

' Twinfield requires that the request to exchange the authorization code for a token must be a GET.
' (In most cases, OAuth2 is implemented where the exchange for token HTTP request is a POST.)
' Note: The exchange-for-token happens within Chilkat in a background thread.  After the user interactively 
' accepts or denies authorization, the browser receives the response and redirects to localhost:<port>,
' where Chilkat is waiting on a background thread to receive the redirect, process it, and then send the HTTP request
' to exchange the code for a token.  This happens internally while your code below is waiting for the authorization..)
oauth2.UncommonOptions = "EXCHANGE_CODE_FOR_TOKEN_USING_GET"

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> 1) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

Debug.Print "url = " & url

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Wait for the user to approve or deny authorization in the browser.
Dim numMsWaited As Long
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response - The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    Debug.Print "No response from the browser!"
    Exit Sub
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    Debug.Print "OAuth2 failed to complete."
    Debug.Print oauth2.FailureInfo
    Exit Sub
End If

If (oauth2.AuthFlowState = 4) Then
    Debug.Print "OAuth2 authorization was denied."
    Debug.Print oauth2.AccessTokenResponse
    Exit Sub
End If

If (oauth2.AuthFlowState <> 3) Then
    Debug.Print "Unexpected AuthFlowState:" & oauth2.AuthFlowState
    Exit Sub
End If

Debug.Print "OAuth2 authorization granted!"
Debug.Print "Access Token = " & oauth2.AccessToken

' Get the full JSON response:
Dim json As New ChilkatJsonObject
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = 0

' The JSON response looks like this:

Debug.Print json.Emit()

' Save the JSON to a file for future requests.
Dim fac As New CkFileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/twinfield.json",json.Emit(),"utf-8",0)