Visual Basic 6.0

Examine Client Certificates for an Accepted TLS Connection

See more Socket/SSL/TLS Examples

Demonstrates how to access the client certificates for a TLS connection accepted by your application acting as the server. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim listenSslSocket As New ChilkatSocket

' An SSL/TLS server needs a digital certificate.  This example loads it from a PFX file.
' This is the server's certificate.

Dim cert As New ChilkatCert
success = cert.LoadPfxFile("qa_data/serverCert/myServerCert.pfx","pfx_password")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' To accept client client certificates in the TLS handshake,
' we must indicate a list of acceptable client certificate root CA DN's
' that are allowed.  (DN is an acronym for Distinguished Name.)
' Call AddSslAcceptableClientCaDn once for each acceptable CA DN.
' Here are a few examples so you can see the general format of a DN.
success = listenSslSocket.AddSslAcceptableClientCaDn("C=SE, O=AddTrust AB, OU=AddTrust External TTP Network, CN=AddTrust External CA Root")
success = listenSslSocket.AddSslAcceptableClientCaDn("O=Digital Signature Trust Co., CN=DST Root CA X3")

' Initialize with our server's TLS certificate.
success = listenSslSocket.InitSslServer(cert)
If (success = 0) Then
    Debug.Print listenSslSocket.LastErrorText
    Exit Sub
End If

' Bind and listen on a port:
Dim myPort As Long
myPort = 8123
' Allow for a max of 5 queued connect requests.
Dim backLog As Long
backLog = 5
success = listenSslSocket.BindAndListen(myPort,backLog)
If (success = 0) Then
    Debug.Print listenSslSocket.LastErrorText
    Exit Sub
End If

' Accept the next incoming connection.
Dim maxWaitMillisec As Long
maxWaitMillisec = 20000

Dim clientSock As New ChilkatSocket
success = listenSslSocket.AcceptNext(maxWaitMillisec,clientSock)
If (success = 0) Then
    Debug.Print listenSslSocket.LastErrorText
    Exit Sub
End If

' Examine the client certs chain.  The 1st cert will be the client certificate, and
' the subsequent certs will be the certs in the chain of authentication.
Dim numClientCerts As Long
numClientCerts = clientSock.NumReceivedClientCerts
Debug.Print "numClientCerts = " & numClientCerts

Dim clientCert As New ChilkatCert
Dim i As Long
i = 0
Do While i < numClientCerts
    success = clientSock.GetRcvdClientCert(i,clientCert)
    Debug.Print clientCert.SubjectDN
    i = i + 1
Loop

' Close the connection with the client
success = clientSock.Close(1000)