(Visual Basic 6.0) SSH Tunnel (Port Forwarding via direct-tcpip channel)

Demonstrates how to create an SSH tunnel to a remote hostname:port via a direct-tcpip channel.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

' Connect to an SSH server:
Dim hostname As String
Dim port As Long

' Hostname may be an IP address or hostname:
hostname = "192.168.1.117"
port = 22

Dim success As Long
success = ssh.Connect(hostname,port)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

' Authenticate using login/password:
success = ssh.AuthenticatePw("chilkat","myPassword")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Open a direct-tcpip channel.  We want the SSH server to connect
' to www.chilkatsoft.com, port 80 (i.e. the web server).
' Data sent through the SSH tunnel is forwarded to the remote
' host:port.  (Note: The remote host:port does not need to be 
' a web server.  It can be anything.  It can be your own
' customer application server that listens on a port, or any
' other type of server.)
' When we read from the SSH channel, we'll be reading data
' sent from the remote host:port (i.e. the web server in this
' example).
Dim channelNum As Long
channelNum = ssh.OpenDirectTcpIpChannel("www.chilkatsoft.com",80)
If (channelNum < 0) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Build a simple HTTP GET request for http://www.chilkatsoft.com/xyz.html
Dim httpReq As String
httpReq = "GET /xyz123.html HTTP/1.1" & vbCrLf & "Host: www.chilkatsoft.com" & vbCrLf & vbCrLf

' Send the HTTP request:
success = ssh.ChannelSendString(channelNum,httpReq,"ansi")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Get the HTTP response.
' First read the HTTP response header which ends with a double CRLF.
' Calling ChannelReceiveUntilMatch will receive until match string is seen,
' or until a timeout occurs (IdleTimeoutMs property).  ChannelReceiveUntilMatch
' may read beyond the match string, but it will stop reading as soon as the match
' string is seen.
Dim caseSensitive As Long
caseSensitive = 0
Dim matchStr As String
matchStr = vbCrLf & vbCrLf
success = ssh.ChannelReceiveUntilMatch(channelNum,matchStr,"ansi",caseSensitive)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Extract the HTTP header from the receive buffer.
' (GetReceiveTextS extracts up to and including the match string from the receive buffer)
Dim responseHeader As String
responseHeader = ssh.GetReceivedTextS(channelNum,matchStr,"ansi")
Debug.Print "---- HTTP Response Header ----"
Debug.Print responseHeader

' Now get the body of the HTTP response (this is the HTML content
' of http://www.chilkatsoft.com/xyz.html
' It's possible we've already received the entire HTTP response in the
' call to ChannelReceiveUntilMatch.  Therefore, we'll poll for any remaining data
' and wait a max of .2 seconds.
Dim numBytesRead As Long
Dim pollTimeoutMs As Long
pollTimeoutMs = 200
numBytesRead = ssh.ChannelPoll(channelNum,pollTimeoutMs)
' We're not checking for an error here.
' A return value of -2 means that no data was available and the poll simply timed out (not an error)
' A return value of -1 indicates an error.
' A return value greater than 0 indicates that additional data was received.

Debug.Print "---- HTML BODY ----"

' Extract the remainder of the accumulated data in the internal receive buffer.
' This should be our HTML body:
Dim htmlBody As String
htmlBody = ssh.GetReceivedText(channelNum,"ansi")
Debug.Print htmlBody

' Close the channel:
success = ssh.ChannelSendClose(channelNum)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Disconnect
ssh.Disconnect