(Visual Basic 6.0) Using sudo in an SSH Shell Session

See more SSH Examples

Demonstrates how to run a command as sudo in a shell session.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

Dim port As Long
port = 22
Dim success As Long
success = ssh.Connect("the-ssh-server.com",port)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Authenticate using login/password:
success = ssh.AuthenticatePw("theSshLogin","theSshPassword")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Start a shell session.
' (The QuickShell method was added in Chilkat v9.5.0.65)
Dim channelNum As Long
channelNum = ssh.QuickShell()
If (channelNum < 0) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Construct a StringBuilder with our command ("ls") run with "sudo"
' Note: The line-endings are potentially important.  Some SSH servers may
' require either LF or CRLF line endings.  (Unix/Linux/OSX servers typically
' use bare-LF line endings.  Windows servers likely use CRLF line endings.)

' Using "sudo -S" causes the sudo prompt to be written to stderr,
' and the password is read from stdin (i.e. from the echo command ouput).
' The sudo commands -p option allows us to set the prompt, and we can set it to
' the empty string, thus eliminating the prompt from the stderr completely.
' This allows us to run the command as root (super-user) with no prompt.
Dim sbCommands As New ChilkatStringBuilder
success = sbCommands.Append("echo ""theSshPassword"" | sudo -S -p """" ls" & vbLf)

' Add another command to echo a marker string that
' we'll use in ChannelReceiveUntilMatch below.
' The use of single quotes around 'IS' is a trick so that the output
' of the command is "THIS IS THE END OF THE SCRIPT", but the terminal echo
' includes the single quotes.  This allows us to read until we see the actual
' output of the last command.
success = sbCommands.Append("echo THIS 'IS' THE END OF THE SCRIPT" & vbLf)

' Send the commands..
success = ssh.ChannelSendString(channelNum,sbCommands.GetAsString(),"ansi")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Send an EOF to indicate no more commands will be sent.
' For brevity, we're not checking the return values of each method call.
' Your code should check the success/failure of each call.
success = ssh.ChannelSendEof(channelNum)

' Receive output up to our marker.
success = ssh.ChannelReceiveUntilMatch(channelNum,"THIS IS THE END OF THE SCRIPT","ansi",1)

' Close the channel.
' It is important to close the channel only after receiving the desired output.
success = ssh.ChannelSendClose(channelNum)

' Get any remaining output..
success = ssh.ChannelReceiveToClose(channelNum)

' Get the complete output for all the commands in the session.
Debug.Print "--- output ----"
Debug.Print ssh.GetReceivedText(channelNum,"ansi")