(Visual Basic 6.0) SSH Quick/Simple Shell Session

See more SSH Examples

Demonstrates the simplified way to run multiple commands in a shell session on an SSH server.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

Dim port As Long
port = 22
Dim success As Long
success = ssh.Connect("the-ssh-server.com",port)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Authenticate using login/password:
success = ssh.AuthenticatePw("theSshLogin","theSshPassword")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Start a shell session.
' (The QuickShell method was added in Chilkat v9.5.0.65)
Dim channelNum As Long
channelNum = ssh.QuickShell()
If (channelNum < 0) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Construct a StringBuilder with multiple commands, one per line.
' Note: The line-endings are potentially important.  Some SSH servers may
' require either LF or CRLF line endings.  (Unix/Linux/OSX servers typically
' use bare-LF line endings.  Windows servers likely use CRLF line endings.)
Dim sbCommands As New ChilkatStringBuilder
success = sbCommands.Append("echo hello world" & vbLf)
success = sbCommands.Append("date" & vbLf)
success = sbCommands.Append("df" & vbLf)

' For our last command, we're going to echo a marker string that
' we'll use in ChannelReceiveUntilMatch below.
' The use of single quotes around 'IS' is a trick so that the output
' of the command is "THIS IS THE END OF THE SCRIPT", but the terminal echo
' includes the single quotes.  This allows us to read until we see the actual
' output of the last command.
success = sbCommands.Append("echo THIS 'IS' THE END OF THE SCRIPT" & vbLf)

' Send the commands..
success = ssh.ChannelSendString(channelNum,sbCommands.GetAsString(),"ansi")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Send an EOF to indicate no more commands will be sent.
' For brevity, we're not checking the return values of each method call.
' Your code should check the success/failure of each call.
success = ssh.ChannelSendEof(channelNum)

' Receive output up to our marker.
success = ssh.ChannelReceiveUntilMatch(channelNum,"THIS IS THE END OF THE SCRIPT","ansi",1)

' Close the channel.
' It is important to close the channel only after receiving the desired output.
success = ssh.ChannelSendClose(channelNum)

' Get any remaining output..
success = ssh.ChannelReceiveToClose(channelNum)

' Get the complete output for all the commands in the session.
Debug.Print "--- output ----"
Debug.Print ssh.GetReceivedText(channelNum,"ansi")

' Here's our actual sample output:

' 	Last login: Thu Dec 22 20:19:09 2016 from chilkat13
' 
' 	echo hello world
' 	date
' 	df
' 	echo THIS 'IS' THE END OF THE SCRIPT
' 	chilkatosx:~ chilkat$ echo hello world
' 	hello world
' 	chilkatosx:~ chilkat$ date
' 	Thu Dec 22 20:30:48 CST 2016
' 	chilkatosx:~ chilkat$ df
' 	Filesystem    512-blocks      Used  Available Capacity  iused     ifree %iused  Mounted on
' 	/dev/disk2    2176716032 265768928 1910435104    13% 33285114 238804388   12%   /
' 	devfs                383       383          0   100%      664         0  100%   /dev
' 	map -hosts             0         0          0   100%        0         0  100%   /net
' 	map auto_home          0         0          0   100%        0         0  100%   /home
' 	/dev/disk3s2      374668    374668          0   100%    93665         0  100%   /Volumes/Google Chrome
' 	chilkatosx:~ chilkat$ echo THIS 'IS' THE END OF THE SCRIPT
' 	THIS IS THE END OF THE SCRIPT
' 	chilkatosx:~ chilkat$