Visual Basic 6.0

Multi-Hop SSH (SSH Through SSH)

See more SSH Examples

Demonstrates how to SSH through one SSH server to get to another SSH server. The scheme looks like this:

Application => ServerSSH1 => ServerSSH2

The ConnectThroughSsh method is added in Chilkat version 9.5.0.55 to accomplish this task. Technically, it should be possible to chain any number of servers using the ConnectThroughSsh multiple times:

Application => ServerSSH1 => ServerSSH2 ==> ServerSSH3 => ... => ServerSSHN

Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh1 As New ChilkatSsh

' Hostname may be an IP address or domain name:
Dim hostname As String
hostname = "192.168.1.108"
Dim port As String
port = 22

' Connect directly to the 1st SSH server:
success = ssh1.Connect(hostname,port)
If (success <> 1) Then
    Debug.Print ssh1.LastErrorText
    Exit Sub
End If

' Wait a max of 15 seconds when reading responses..
ssh1.IdleTimeoutMs = 15000

' Authenticate using login/password:
success = ssh1.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Debug.Print ssh1.LastErrorText
    Exit Sub
End If

' Connect through the 1st SSH connection to reach a 2nd SSH server.
' Note: Any number of SSH connections may be simultaneously tunneled through a single
' existing SSH connection.
Dim ssh2 As New ChilkatSsh
success = ssh2.ConnectThroughSsh(ssh1,"someremoteserver.com",22)
If (success <> 1) Then
    Debug.Print ssh2.LastErrorText
    Exit Sub
End If

ssh2.IdleTimeoutMs = 15000

' Authenticate with ssh2...
success = ssh2.AuthenticatePw("myLogin2","myPassword2")
If (success <> 1) Then
    Debug.Print ssh2.LastErrorText
    Exit Sub
End If

' The application may now is connected and authenticated with ssh2.
' The application can do whatever it desires just as if it was directly
' connected to ssh2.   For example, the application might open
' a session channel to send commands or start a remote shell..
Dim channelNum As Long
channelNum = ssh2.OpenSessionChannel()
If (channelNum < 0) Then
    Debug.Print ssh2.LastErrorText
    Exit Sub
End If

' ...
' ...
' ...

' Close the connection with ssh2.  (This closes the the tunnel through ssh1.)
' The connection with ssh1 is still alive, and may be used for more connections.
ssh2.Disconnect 

' ...
' ...
' ...

ssh1.Disconnect