Visual Basic 6.0

SSH Keyboard Authentication

See more SSH Examples

Demonstrates how to implement keyboard authentication with an SSH server. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

' Set some timeouts, in milliseconds:
ssh.ConnectTimeoutMs = 5000
ssh.IdleTimeoutMs = 15000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
Dim hostname As String
hostname = "sftp.example.com"
Dim port As Long
port = 22
success = ssh.Connect(hostname,port)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Begin keyboard authentication..
Dim xmlResponse As String
xmlResponse = ssh.StartKeyboardAuth("myLogin")
If (ssh.LastMethodSuccess <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' If a user authentication banner was received, then your app
' may display it prior to prompting for the password.
Debug.Print "UserAuthBanner: " & ssh.UserAuthBanner

Dim xml As New ChilkatXml

success = xml.LoadXml(xmlResponse)
' Assume LoadXml succeeds for the example..
If (xml.HasChildWithTag("success") = 1) Then
    Debug.Print "No password required, already authenticated."
    Exit Sub
End If

If (xml.HasChildWithTag("error") = 1) Then
    Debug.Print "Authentication already failed."
    Exit Sub
End If

' See the online reference documentation for Chilkat SSH.
' The XML returned by StartKeyboardAuth will contain an infoRequest
' with one or more prompts that your application may choose to display.

' Call ContinueKeyboardAuth, passing in the whatever information is requires (such as the password).
' Typically, keyboard authentication requires one call to ContinueKeyboardAuth 
' using the password.  Theoretically, the SSH server could prompt for additional pieces
' of information.  The authentication is completed when the XML returned contains
' either a "success" or "error" child node.

' This example asumes only one call to ContinueKeyboardAuth is required.
xmlResponse = ssh.ContinueKeyboardAuth("myPassword")
If (ssh.LastMethodSuccess <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

success = xml.LoadXml(xmlResponse)
' Assume LoadXml succeeds for the example..
If (xml.HasChildWithTag("success") = 1) Then
    Debug.Print "SSH Keyboard Authentication Successful!"
    Exit Sub
End If

If (xml.HasChildWithTag("error") = 1) Then
    Debug.Print "Authentication failed."
    Exit Sub
End If