(Visual Basic 6.0) SSH Exec (Execute Command Line)

Shows how to execute a command on an SSH server and retrieve the command output.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

' Connect to an SSH server:
Dim hostname As String
Dim port As Long

' Hostname may be an IP address or hostname:
hostname = "192.168.1.108"
port = 22

Dim success As Long
success = ssh.Connect(hostname,port)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

' Authenticate using login/password:
success = ssh.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Open a session channel.  (It is possible to have multiple
' session channels open simultaneously.)
Dim channelNum As Long
channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' The SendReqExec method starts a command on the remote
' server.   The syntax of the command string depends on the
' default shell used on the remote server to run the command.
' On Windows systems it is CMD.EXE.  On UNIX/Linux
' systems the user's default shell is typically defined in /etc/password.

' Here are some examples of command lines for <b>Windows SSH servers</b>:

' Get a directory listing:
Dim cmd1 As String
cmd1 = "dir"

' Do a nameserver lookup:
Dim cmd2 As String
cmd2 = "nslookup chilkatsoft.com"

' List a specific directory.  Given that the shell is CMD.EXE, backslashes must
' be used:
Dim cmd3 As String
cmd3 = "dir \temp"

' Execute a sequence of commands.  The syntax for CMD.EXE may be found
' here: http://technet.microsoft.com/en-us/library/bb490880.aspx.  Notice how the commands
' are separated by "&&" and the entire command must be enclosed in quotes:
Dim cmd4 As String
cmd4 = """cd \temp&&dir"""

' Here are two examples of command lines for <b>Linux/UNIX SSH servers</b>:

' Get a directory listing:
Dim cmd5 As String
cmd5 = "ls -l /tmp"

' Run a series of commands (syntax may depend on your default shell):
Dim cmd6 As String
cmd6 = "cd /etc; ls -la"

' Request a directory listing on the remote server:
' If your server is Windows, change the string from "ls" to "dir"
success = ssh.SendReqExec(channelNum,"ls")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Call ChannelReceiveToClose to read 
' output until the server's corresponding "channel close" is received.
success = ssh.ChannelReceiveToClose(channelNum)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Let's pickup the accumulated output of the command:
Dim cmdOutput As String
cmdOutput = ssh.GetReceivedText(channelNum,"ansi")
If (ssh.LastMethodSuccess <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Display the remote shell's command output:
Debug.Print cmdOutput

' Disconnect
ssh.Disconnect