(Visual Basic 6.0) SSH to Cisco Switch - Processing "More" Responses

Demonstrates connecting to a Cisco switch, running a command to enable privileged mode, then running a command to get a paged response requiring the SPACE char to be sent to process "--More--".

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

Dim success As Long
success = ssh.Connect("SSH_SERVER_DOMAIN_OR_IP_ADDRESS",22)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Authenticate using login/password:
success = ssh.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Start a shell session.
Dim channelNum As Long
channelNum = ssh.QuickShell()
If (channelNum < 0) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' If the CISCO switch returns a prompt with ">", then read until we get the prompt.
' (It's not actually required that we do this, but it helps to know that all is OK at this point..)
success = ssh.ChannelReceiveUntilMatch(channelNum,">","utf-8",1)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Show what we received so far:
Debug.Print ssh.GetReceivedText(channelNum,"utf-8")

' Send the "ena" command to enable privileged mode.
' (For the Cisco switch, terminate command with a single CR char.)
success = ssh.ChannelSendString(channelNum,"ena" & vbCr,"utf-8")
' Assume success for this example to make it shorter..

' Read to the "Password:" prompt.
success = ssh.ChannelReceiveUntilMatch(channelNum,"Password:","utf-8",1)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Show what we received...
Debug.Print ssh.GetReceivedText(channelNum,"utf-8")

' Send the password.
success = ssh.ChannelSendString(channelNum,"MY_PASSWORD_FOR_ELEVATED_PRIVILEGE" & vbCr,"utf-8")

' The prompt now changes from "Something>" to "Something#>
' Read until the new prompt..
success = ssh.ChannelReceiveUntilMatch(channelNum,"#","utf-8",1)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Show what we received...
Debug.Print ssh.GetReceivedText(channelNum,"utf-8")

' Send the "show running-config" command.
' The response will be in multiple pages, each ending with "--More--" and requiring a SPACE bar to be sent
' to get the next page.
success = ssh.ChannelSendString(channelNum,"show running-config" & vbCr,"utf-8")

' Consume the response until we end with another prompt.
Dim saMatch As New CkStringArray
' Change "YOUR_PROMPT" to your actual prompt.  We don't want to check for only "#" because
' it's not specific enough.  The data in the response could contain the "#" char...
success = saMatch.Append("YOUR_PROMPT#")
success = saMatch.Append("--More--")

Dim sbReceived As New ChilkatStringBuilder
Dim moreComing As Long
moreComing = 1
Do While (moreComing = 1)

    success = ssh.ChannelReceiveUntilMatchN(channelNum,saMatch,"utf-8",1)
    If (success <> 1) Then
        Debug.Print ssh.LastErrorText
        Exit Sub
    End If

    moreComing = 0

    sbReceived.Clear 
    success = sbReceived.Append(ssh.GetReceivedText(channelNum,"utf-8"))

    Debug.Print sbReceived.GetAsString()

    If (sbReceived.Contains("--More--",1) = 1) Then
        moreComing = 1

        ' Send a SPACE char just as if we were interactively pressing the SPACE key to get more output.
        success = ssh.ChannelSendString(channelNum," ","utf-8")
    End If

Loop

ssh.Disconnect