Visual Basic 6.0
SQS Delete Message

Deletes a message from an SQS queue. You specify the message by using the message's receipt handle and not the message ID you received when you sent the message. This example will first receive a message, and then use the receipt handle to delete it.
See SQS DeleteMessage or detailed information.
Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0
Visual Basic 6.0
Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server.
' such as https://sqs.us-west-2.amazonaws.com/
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("sqs.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sqs"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","ReceiveMessage")
success = rest.AddQueryParam("MaxNumberOfMessages","5")
success = rest.AddQueryParam("VisibilityTimeout","15")
success = rest.AddQueryParam("AttributeName","All")
success = rest.AddQueryParam("MessageAttributeName","All")

' Use the actual path part of your SQS queue URL here:
Dim responseXml As String
responseXml = rest.FullRequestNoBody("GET","/123456789123/chilkatTest")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = " & rest.ResponseStatusCode
    Debug.Print "response status text = " & rest.ResponseStatusText
    Debug.Print "response header: " & rest.ResponseHeader
    Debug.Print "response body: " & responseXml
    Exit Sub
End If

' Examine the successful XML response.
Dim xml As New ChilkatXml
success = xml.LoadXml(responseXml)

' A successful response looks like this:
' <?xml version="1.0" encoding="utf-8" ?>
' <ReceiveMessageResponse xmlns="http://queue.amazonaws.com/doc/2012-11-05/">
'     <ReceiveMessageResult>
'         <Message>
'             <Body>this is a test</Body>
'             <MD5OfBody>54b0c58c7ce9f2a8b551351102ee0938</MD5OfBody>
'             <ReceiptHandle>AQEBMyLof...UbKBTvHtEg==</ReceiptHandle>
'             <Attribute>
'                 <Name>SenderId</Name>
'                 <Value>957491831129</Value>
'             </Attribute>
' ...
' ...
'             <MessageId>52882c65-5e21-4450-9024-93a3b01e61d3</MessageId>
'             <MD5OfMessageAttributes>2ff68603f4239272bd03f543254ed040</MD5OfMessageAttributes>
'         </Message>
'     </ReceiveMessageResult>
'     <ResponseMetadata>
'         <RequestId>05ba5c92-80ee-5f87-be76-0cf67b7475d6</RequestId>
'     </ResponseMetadata>
' </ReceiveMessageResponse>

' Get some values from the XML:
Dim receiptHandle As String
receiptHandle = xml.ChilkatPath("ReceiveMessageResult|Message|ReceiptHandle|*")
Debug.Print "ReceiptHandle = " & receiptHandle

' Now use the receipt handle to delete the message.
' Use the same connection (or automatically reconnect if needed)
success = rest.ClearAllQueryParams()

success = rest.AddQueryParam("Action","DeleteMessage")
success = rest.AddQueryParam("ReceiptHandle",receiptHandle)

' Use the actual path part of your SQS queue URL here:
responseXml = rest.FullRequestNoBody("GET","/123456789123/chilkatTest")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = " & rest.ResponseStatusCode
    Debug.Print "response status text = " & rest.ResponseStatusText
    Debug.Print "response header: " & rest.ResponseHeader
    Debug.Print "response body: " & responseXml
    Exit Sub
End If

' Examine the successful XML response.
success = xml.LoadXml(responseXml)
Debug.Print xml.GetXml()

' A successful DeleteMessage response looks like this:
' <DeleteMessageResponse>
'     <ResponseMetadata>
'         <RequestId>
'             b5293cb5-d306-4a17-9048-b263635abe42
'         </RequestId>
'     </ResponseMetadata>
' </DeleteMessageResponse>