(Visual Basic 6.0) Using the Disk Cache

The Chilkat Spider component has disk caching capabilities. To setup a disk cache, create a new directory anywhere on your local hard drive and set the CacheDir property to the path. For example, you might create "c:/spiderCache/". The UpdateCache property controls whether downloaded pages are saved to the cache. The FetchFromCache property controls whether the cache is first checked for pages. The LastFromCache property tells whether the last URL fetched came from cache or not.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim spider As New ChilkatSpider

' Set our cache directory and make sure saving-to-cache and fetching-from-cache
' are both turned on:
spider.CacheDir = "c:/spiderCache/"
spider.FetchFromCache = 1
spider.UpdateCache = 1

' If you run this code twice, you'll find that the 2nd run is extremely fast
' because the pages will be retrieved from cache.

' The spider object crawls a single web site at a time.  As you'll see
' in later examples, you can collect outbound links and use them to 
' crawl the web.  For now, we'll simply spider 10 pages of chilkatsoft.com
spider.Initialize "www.chilkatsoft.com"

' Add the 1st URL:
spider.AddUnspidered "http://www.chilkatsoft.com/"

' Begin crawling the site by calling CrawlNext repeatedly.
Dim i As Long
For i = 0 To 9
    Dim success As Long
    success = spider.CrawlNext()
    If (success = 1) Then
        ' Show the URL of the page just spidered.
        Debug.Print spider.LastUrl
        ' The HTML is available in the LastHtml property
    Else
        ' Did we get an error or are there no more URLs to crawl?
        If (spider.NumUnspidered = 0) Then
            Debug.Print "No more URLs to spider"
        Else
            Debug.Print spider.LastErrorText
        End If

    End If

    ' Sleep 1 second before spidering the next URL.
    ' The reason for waiting a short time before the next fetch is to prevent
    ' undue stress on the web server.  However, if the last page was retrieved
    ' from cache, there is no need to pause.
    If (spider.LastFromCache <> 1) Then
        spider.SleepMs 1000
    End If

Next