(Visual Basic 6.0) Create Restricted Data Token (RDT)

See more Amazon SP-API Examples

Returns a Restricted Data Token (RDT) for one or more restricted resources that you specify.

For more information, see https://developer-docs.amazon.com/sp-api/docs/tokens-api-v2021-03-01-reference#post-tokens2021-03-01restricteddatatoken

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "execute-api"
' Use the region that is correct for your needs.
authAws.Region = "eu-west-1"

Dim rest As New ChilkatRest
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
' The sandbox endpoint (sandbox.sellingpartnerapi-eu.amazon.com) fails.
' Use the production endpoint and see the note below.
Dim success As Long
success = rest.Connect("sellingpartnerapi-eu.amazon.com",port,bTls,bAutoReconnect)
If (success = 0) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

success = rest.SetAuthAws(authAws)

' Load the previously obtained LWA access token.
' See Fetch SP-API LWA Access Token
Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/sp_api_lwa_token.json")
If (success = 0) Then
    Debug.Print "Failed to load LWA access token."
    Exit Sub
End If

' Add the x-amz-access-token request header.
Dim lwa_token As String
lwa_token = jsonToken.StringOf("access_token")
success = rest.ClearAllHeaders()
success = rest.AddHeader("x-amz-access-token",lwa_token)

' We're going to send a POST with the following JSON body:

' {
'   "restrictedResources": [
'     {
'       "method": "GET",
'       "path": "/orders/v0/orders",
'       "dataElements": ["buyerInfo", "shippingAddress"]
'     }
'   ]
' }

' Use this online tool to generate code from sample JSON: 
' Generate Code to Create JSON

Dim json As New ChilkatJsonObject
success = json.UpdateString("restrictedResources[0].method","GET")
success = json.UpdateString("restrictedResources[0].path","/orders/v0/orders")
success = json.UpdateString("restrictedResources[0].dataElements[0]","buyerInfo")
success = json.UpdateString("restrictedResources[0].dataElements[1]","shippingAddress")

Dim sbRequest As New ChilkatStringBuilder
success = json.EmitSb(sbRequest)

Dim sbResponse As New ChilkatStringBuilder
Dim uri As String
uri = "/tokens/2021-03-01/restrictedDataToken"
success = rest.FullRequestSb("POST",uri,sbRequest,sbResponse)
If (success = 0) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' ------------------------------------------------------------------------------------
' Note: Using the sandbox endpoint, such as sandbox.sellingpartnerapi-eu.amazon.com
' results in a response status code of 400 with the following error:
' [{"code":"InvalidInput","message":"Could not match input arguments"}]
' Getting a restricted data token seems to only work with the production endpoint.
' ------------------------------------------------------------------------------------

' Examine the response status.
Dim statusCode As Long
statusCode = rest.ResponseStatusCode
If (statusCode <> 200) Then
    Debug.Print "Response status code: " & statusCode
    Debug.Print "Response status text: " & rest.ResponseStatusText
    Debug.Print "Response body: "
    Debug.Print sbResponse.GetAsString()
    Debug.Print "Failed."
    Exit Sub
End If

Debug.Print sbResponse.GetAsString()

' If successful, gets a JSON response such as the following:

' {
'   "expiresIn": 3600,
'   "restrictedDataToken": "Atz.sprdt|AYAB.....TQ="
' }

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

Dim jsonResp As New ChilkatJsonObject
success = jsonResp.LoadSb(sbResponse)

Dim expiresIn As Long
expiresIn = jsonResp.IntOf("expiresIn")
Dim restrictedDataToken As String
restrictedDataToken = jsonResp.StringOf("restrictedDataToken")

' Save the RDT for subsequent use..
success = jsonResp.WriteFile("qa_data/tokens/sp_api_rdt_token.json")

Debug.Print "Success!"