Visual Basic 6.0

Debugging with Socket Session Logging

See more Socket/SSL/TLS Examples

Debugging with socket session logging.

The Chilkat Socket component provides properties for keeping a session log making it possible to see the exact bytes received and sent on a TCP/IP or SSL connection. To enable session logging, set the KeepSessionLog property = _TRUE_. The SessionLogEncoding property controls how binary, non-printable bytes are represented in the log. There are two possible settings: Possible values are "esc" and "hex". The default value is "esc".

When set to "hex", the bytes are encoded as a hexidecimalized string. The "esc" encoding is a C-string like encoding, and is more compact than hex if most of the data to be logged is text. Printable us-ascii chars are unmodified. Common "C" control chars are represented as "\r", "\n", "\t", etc. Non-printable and byte values greater than 0x80 are escaped using a backslash and hex encoding: \xHH. Certain printable chars are backslashed: SPACE, double-quote, single-quote, etc.

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim socket As New ChilkatSocket

' Enable session logging:
socket.KeepSessionLog = 1
socket.SessionLogEncoding = "esc"

' To demonstrate session logging, we'll connect to an
' HTTP server and download the HTTP response header:
Dim ssl As Long
ssl = 0
Dim maxWaitMillisec As Long
maxWaitMillisec = 20000
success = socket.Connect("www.chilkatsoft.com",80,ssl,maxWaitMillisec)
If (success <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Set maximum timeouts for reading an writing (in millisec)
socket.MaxReadIdleMs = 10000
socket.MaxSendIdleMs = 10000

' The socket component includes a BuildHttpGetRequest
' method for convenience. Build a GET and send it to 
' the web server:
Dim httpGet As String
httpGet = socket.BuildHttpGetRequest("http://www.chilkatsoft.com/")

' Send it...
success = socket.SendString(httpGet)
If (success <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Read the response up to the first double CRLF:
Dim httpHeader As String
httpHeader = socket.ReceiveUntilMatch(vbCrLf & vbCrLf)
If (socket.LastMethodSuccess <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Close the connection with the server
' Wait a max of 20 seconds (20000 millsec)
success = socket.Close(20000)

' Display the session log:
Debug.Print socket.SessionLog

' Show the HTTP response header:
Debug.Print httpHeader