(Visual Basic 6.0) Socket Send/Receive 16-bit Integers

Demonstrates sending and receiving 16-bit integers over a socket connection using either big-endian or little-endian byte ordering.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim sock As New ChilkatSocket

' --------------------------------------------------------------------
' This example uses the public TCP echo service at https://tcpbin.com/
' --------------------------------------------------------------------

Dim useTls As Long
useTls = 0
Dim port As Long
port = 4242
Dim maxWaitMs As Long
maxWaitMs = 5000
Dim success As Long
success = sock.Connect("tcpbin.com",port,useTls,maxWaitMs)
If (success = 0) Then
    Debug.Print sock.LastErrorText
    Exit Sub
End If

' Wait a max of 2 seconds for a response..
sock.MaxReadIdleMs = 2000

' Send a 16-bit integer using big-endian byte ordering (also called network byte order)
' 12022 decimal = 2EF6 hex
Dim value As Long
value = 12022
Dim bigEndian As Long
bigEndian = 1
success = sock.SendInt16(value,bigEndian)
' Send it again, because we'll read it two different ways..
success = sock.SendInt16(value,bigEndian)

' The tcpbin.com echo server only echoes after receiving an LF (linefeed char)
success = sock.SendByte(10)

' Let's see hex values of the 2 bytes sent in network byte order (big-endian)
' (The echo server sends back exactly the bytes received.)
Dim hexStr As String
hexStr = sock.ReceiveNBytesENC(2,"hex")

' In the big-ending byte order, the byte order is most significant byte to least significant,
' therefore we should see the bytes in the order 0x2E 0xF6.
Debug.Print "Expecting big-endian 2EF6"
Debug.Print hexStr

' Let's read directly to an integer..
success = sock.ReceiveInt16(bigEndian,1)
Debug.Print "Expecting 12022"
Debug.Print "Received: " & sock.ReceivedInt

' Consume the LF that gets echoed back..
success = sock.ReceiveByte(1)

' --------------------------------------------------------------------
' Let's do the same thing, but with little-endian byte ordering.

Debug.Print "----"

' 12022 decimal = 2EF6 hex, but little-endian byte ordering will send the bytes in the order 0xF6 0x2E
value = 12022
bigEndian = 0
success = sock.SendInt16(value,bigEndian)
success = sock.SendInt16(value,bigEndian)
success = sock.SendByte(10)

hexStr = sock.ReceiveNBytesENC(2,"hex")

Debug.Print "Expecting little-endian F62E"
Debug.Print hexStr

success = sock.ReceiveInt16(bigEndian,1)
Debug.Print "Expecting 12022"
Debug.Print "Received: " & sock.ReceivedInt

' Consume the LF that gets echoed back..
success = sock.ReceiveByte(1)

success = sock.Close(1000)

' Output:

' Expecting big-endian 2EF6
' 2EF6
' Expecting 12022
' Received: 12022
' ----
' Expecting little-endian F62E
' F62E
' Expecting 12022
' Received: 12022