(Visual Basic 6.0) Receive Text until CRLF

Demonstrates receiving text on a socket connection up to and including when an expected CRLF arrives. The example sends an HTTP HEAD request to an HTTP server and then reads the response header using ReceiveToCRLF and ReceiveUntilMatch.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim socket As New ChilkatSocket

' Connect using TLS to www.chilkatsoft.com
' We could also use a normal TCP connection also by specifying port 80 with useTls = 0.
Dim useTls As Long
useTls = 1
Dim maxWaitMillisec As Long
maxWaitMillisec = 20000
Dim success As Long
success = socket.Connect("www.chilkatsoft.com",443,useTls,maxWaitMillisec)
If (success <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Tell the socket object that all text is to be sent in the utf-8 encoding,
' and the text received is assumed to be utf-8.
socket.StringCharset = "utf-8"

' Send an HTTP HEAD request:
success = socket.SendString("HEAD / HTTP/1.1" & vbCrLf & "Host: www.chilkatsoft.com" & vbCrLf & vbCrLf)
If (success <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Wait a maximum of 4 seconds while no data is forthcoming:
socket.MaxReadIdleMs = 4000

' To explain MaxReadIdleMs further:  In Chilkat, a max "idle timeout" is the max time to wait
' while no additional data arrives on the socket.  Imagine if 10MB of data will be received
' where the 1st CRLF occurs at the very end.  As long as the data continues arriving and does not
' halt for more than 4000ms, then the ReceiveToCRLF will continue receiving.  It is only after
' the connection becomes idle for more than 4000ms that the app will giveup and fail the read.

' Get the 1st response line, which should be "HTTP/1.1 200 OK"
Dim responseStatusLine As String
responseStatusLine = socket.ReceiveToCRLF()
If (socket.LastMethodSuccess <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

Debug.Print "StatusLine: " & responseStatusLine

' Now get the 1st line of the response header:
Dim responseHeaderLine As String
responseHeaderLine = socket.ReceiveToCRLF()
If (socket.LastMethodSuccess <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

Debug.Print "HeaderLine: " & responseHeaderLine

' Now read the remainder of the response header by reading until a double CRLF is seen:
Dim remainderOfHeader As String
remainderOfHeader = socket.ReceiveUntilMatch(vbCrLf & vbCrLf)
If (socket.LastMethodSuccess <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

Debug.Print "Remainder: " & remainderOfHeader

' Close the connection with the server
' Wait a max of 20 seconds (20000 millsec)
success = socket.Close(20000)