(Visual Basic 6.0) Send SOAP 1.2 Request to Web Service Requiring Authentication

This example demonstrates sending a SOAP 1.2 request to a web service that requires both HTTP authentication in the Authorization request header, as well as a service-defined password in the XML body of the request.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat HTTP API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

Dim http As New ChilkatHttp

' We are sending the following POST:

' POST /wsSome_Testes/Service.asmx HTTP/1.1
' Host: www.something.com
' Content-Type: application/soap+xml; charset=utf-8
' Content-Length: length
' 
' <?xml version="1.0" encoding="utf-8"?>
' <soap12:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap12="http://www.w3.org/2003/05/soap-envelope">
'   <soap12:Body>
'     <GetXYZbyABC xmlns="http://tempuri.org/">
'       <ABCBEN>string</ABCBEN>
'       <ABC>string</ABC>
'       <NumLocal>int</NumLocal>
'       <Password>string</Password>
'       <MsgErro>string</MsgErro>
'     </GetXYZbyABC>
'   </soap12:Body>
' </soap12:Envelope>
' 

' First, specify the login/password for the Authorization request header (not shown in the headers above).
http.Login = "YOUR_LOGIN"
' The need for a login domain depends on the web service..
http.LoginDomain = "YOUR_DOMAIN"
http.Password = "YOUR_PASSWORD"

' Build the SOAP XML shown above:
' Replace VAL_ABCBEN, VAL_ABC, VAL_NUMLOCAL, and YOUR_SOAP_BODY_PASSWORD with actual values..
Dim xml As New ChilkatXml
xml.Tag = "soap12:Envelope"
success = xml.AddAttribute("xmlns:xsi","http://www.w3.org/2001/XMLSchema-instance")
success = xml.AddAttribute("xmlns:xsd","http://www.w3.org/2001/XMLSchema")
success = xml.AddAttribute("xmlns:soap12","http://www.w3.org/2003/05/soap-envelope")
success = xml.UpdateAttrAt("soap12:Body|GetXYZbyABC",1,"xmlns","http://tempuri.org/")
xml.UpdateChildContent "soap12:Body|GetXYZbyABC|ABCBEN","VAL_ABCBEN"
xml.UpdateChildContent "soap12:Body|GetXYZbyABC|ABC","VAL_ABC"
xml.UpdateChildContent "soap12:Body|GetXYZbyABC|NumLocal","VAL_NUMLOCAL"
xml.UpdateChildContent "soap12:Body|GetXYZbyABC|Password","YOUR_SOAP_BODY_PASSWORD"
xml.UpdateChildContent "soap12:Body|GetXYZbyABC|MsgErro","x"

' Set the Content-Type of the request.
http.SetRequestHeader "Content-Type","application/soap+xml"

' We don't need to specify the Content-Length or Host headers.  Chilkat automatically adds them.

' Send the request...
Dim resp As ChilkatHttpResponse
Set resp = http.PostXml("https://www.something.com/wsSome_Testes/Service.asmx",xml.GetXml(),"utf-8")
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "Response Status Code = " & resp.StatusCode

Dim respXml As New ChilkatXml
success = respXml.LoadXml(resp.BodyStr)

Debug.Print "Response XML:"
Debug.Print respXml.GetXml()

' The response XML should look like this:

' <?xml version="1.0" encoding="utf-8"?>
' <soap12:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap12="http://www.w3.org/2003/05/soap-envelope">
'   <soap12:Body>
'     <GetXYZbyABCResponse xmlns="http://tempuri.org/">
'       <GetXYZbyABCResult>int</GetXYZbyABCResult>
'       <MsgErro>string</MsgErro>
'     </GetXYZbyABCResponse>
'   </soap12:Body>
' </soap12:Envelope>