(Visual Basic 6.0) SNS List Topics

List the existing SNS topics.

See SNS List Topics for more information.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server.
' such as https://sns.us-west-2.amazonaws.com/
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
Dim success As Long
success = rest.Connect("sns.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sns"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","ListTopics")

Dim responseXml As String
responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = " & rest.ResponseStatusCode
    Debug.Print "response status text = " & rest.ResponseStatusText
    Debug.Print "response header: " & rest.ResponseHeader
    Debug.Print "response body: " & responseXml
    Exit Sub
End If

' Examine the successful XML response (shown below)
Dim xml As New ChilkatXml
success = xml.LoadXml(responseXml)
Debug.Print xml.GetXml()

' To iterate over the TopicArn's
Dim notUsed As String
notUsed = xml.ChilkatPath("ListTopicsResult|Topics|$")
Dim i As Long
i = 0
Dim numTopics As Long
numTopics = xml.NumChildren
Do While i < numTopics
    success = xml.GetChild2(i)
    Debug.Print xml.GetChildContent("TopicArn")
    success = xml.GetParent2()
    i = i + 1
Loop
xml.GetRoot2 

' A sample successful response:
' <?xml version="1.0" encoding="utf-8" ?>
' <ListTopicsResponse xmlns="http://sns.amazonaws.com/doc/2010-03-31/">
'     <ListTopicsResult>
'         <Topics>
'             <member>
'                 <TopicArn>arn:aws:sns:us-west-2:957491831129:chilkat</TopicArn>
'             </member>
'             <member>
'                 <TopicArn>arn:aws:sns:us-west-2:957491831129:chilkat123</TopicArn>
'             </member>
'             <member>
'                 <TopicArn>arn:aws:sns:us-west-2:957491831129:chilkatses</TopicArn>
'             </member>
'         </Topics>
'     </ListTopicsResult>
'     <ResponseMetadata>
'         <RequestId>54514f94-b07d-5f0b-9c8a-1ff85ff4ac65</RequestId>
'     </ResponseMetadata>
' </ListTopicsResponse>