(Visual Basic 6.0) SNS Create Topic

Creates a new SNS topic.

See SNS CreateTopic for more information.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server.
' such as https://sns.us-west-2.amazonaws.com/
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
Dim success As Long
success = rest.Connect("sns.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sns"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","CreateTopic")
success = rest.AddQueryParam("Name","chilkat")

Dim responseXml As String
responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = " & rest.ResponseStatusCode
    Debug.Print "response status text = " & rest.ResponseStatusText
    Debug.Print "response header: " & rest.ResponseHeader
    Debug.Print "response body: " & responseXml
    Exit Sub
End If

' Examine the successful XML response.
Dim xml As New ChilkatXml
success = xml.LoadXml(responseXml)
Debug.Print xml.GetXml()

' To get the TopicArn or RequestId
Debug.Print "TopicArn: " & xml.ChilkatPath("CreateTopicResult|TopicArn|*")
Debug.Print "RequestId: " & xml.ChilkatPath("ResponseMetadata|RequestId|*")

' A sample successful response:
' <?xml version="1.0" encoding="utf-8" ?>
' <CreateTopicResponse xmlns="http://sns.amazonaws.com/doc/2010-03-31/">
'     <CreateTopicResult>
'         <TopicArn>arn:aws:sns:us-west-2:123491831234:chilkat</TopicArn>
'     </CreateTopicResult>
'     <ResponseMetadata>
'         <RequestId>abcd1234-d61a-5115-83bd-abcdabcd6961</RequestId>
'     </ResponseMetadata>
' </CreateTopicResponse>