Visual Basic 6.0

Send Signed Email using PFX File (long version)

Demonstrates how to send a signed email using a digital certificate w/ private key stored in a PFX file. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for sending and receiving email.
Dim mailman As New ChilkatMailMan

' Set the SMTP server.
mailman.SmtpHost = "smtp.mymailserver.com"

' Create a new email object
Dim email As New ChilkatEmail

email.Subject = "This email is signed"
email.Body = "This is a digitally signed mail"
email.From = "Chilkat Admin <admin@chilkatsoft.com>"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")

' Indicate that the email should be sent signed.
email.SendSigned = 1

' Load a PFX file into a certificate store object.
' Then locate the certificate matching the  sender's email address,
' and use it for signing.
' (a PFX file may contain more than one certificate.)
Dim certStore As New ChilkatCertStore
' The 1st argument is the path of the PFX file, the 2nd arg is the 
' PFX file's password:
success = certStore.LoadPfxFile("/pfx_files/chilkatsoft_secret.pfx","secret")
If (success <> 1) Then
    Debug.Print certStore.LastErrorText
    Exit Sub
End If

' Find the certificate for the email address:
Dim jsonE As New ChilkatJsonObject
success = jsonE.UpdateString("email","admin@chilkatsoft.com")

Dim cert As New ChilkatCert
success = certStore.FindCert(jsonE,cert)
If (success = 0) Then
    Debug.Print certStore.LastErrorText
    Exit Sub
End If

' Alternatively, if a PFX file is known to contain a single certificate,
' you may load it directly into a Chilkat certificate object.
' This snippet of source code shows how:
Dim cert2 As New ChilkatCert
' The 1st argument is the filename, the 2nd arg is the 
' PFX file's password:
success = cert2.LoadPfxFile("/pfx_files/chilkatsoft_secret.pfx","secret")
If (success <> 1) Then
    Debug.Print cert2.LastErrorText
    Exit Sub
End If

' This example will use the cert from the certStore...
success = email.SetSigningCert(cert)

' Signed email can be sent in two different ways.  
' In a multipart/signed email, the signature is attached as a separate MIME part.
' In an opaque email (signedData) the content of the email is encapsulated within the signature
' and the email is sent as "application/pkcs7-mime". 
' Either should be fine, but some receiving systems might require one or the other..
mailman.OpaqueSigning = 0

' Send a signed email.
success = mailman.SendEmail(email)
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
Else
    ' The LastErrorText property provides information
    ' even when successful.
    Debug.Print mailman.LastErrorText
    Debug.Print "Mail Sent!"
End If