Visual Basic 6.0

Sending S/MIME Encrypted Email

Sends an encrypted email using the recipient's digital certificate from a .cer file. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for sending and receiving email.
Dim mailman As New ChilkatMailMan

' Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

' Load the .cer file into a certificate object.
' When sending S/MIME encrypted email, it is the recipient's
' certificate that is used for encryption.  Only the public key
' is needed to encrypt.  The recipient is the only
' one possessing the private key, and therefore is the only
' one able to decrypt.
Dim cert As New ChilkatCert
success = cert.LoadFromFile("cknotes.cer")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Create a new email object
Dim email As New ChilkatEmail

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Chilkat Support <support@chilkatsoft.com>"
success = email.AddTo("Chilkat Blog","admin@cknotes.com")

' Indicate that the email is to be sent encrypted.
email.SendEncrypted = 1

' Specify the certificate to be used for encryption.
success = email.SetEncryptCert(cert)

success = mailman.SendEmail(email)
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
Else
    Debug.Print "Mail Sent!"
End If