Sample code for 30+ languages & platforms
Visual Basic 6.0 Requires Chilkat v11.0.0+

Outlook.com SMTP: Replace Password Login with OAuth2

See more SMTP Examples

This replacement for the older password-login sample tests OAuth2 authentication without sending a message. The historical filename is retained for existing links. Setting OAuth2AccessToken makes Chilkat use XOAUTH2; leave SmtpPassword empty. No session log or token is printed.

Personal Outlook.com: This includes Microsoft-hosted Outlook.com, Hotmail, and Live mailboxes. Use delegated OAuth2; ordinary passwords and app passwords are not a replacement for Modern Authentication. SMTP uses smtp-mail.outlook.com:587 with STARTTLS; incoming IMAP/POP use outlook.office365.com on ports 993/995 with implicit TLS. Enable POP or IMAP under Settings > Mail > Forwarding and IMAP before using that protocol. See current Outlook.com settings.

First authorize the account with https://outlook.office.com/SMTP.Send and offline_access, then refresh the access token when needed. This example reads qa_data/tokens/hotmail.json from a private working directory. Microsoft Graph permissions such as Mail.Send or Mail.Read do not authorize these mail protocols. Do not print tokens or authentication logs.

Microsoft reference documentation

Chilkat Visual Basic 6.0 Downloads

Visual Basic 6.0
Dim success As Long
success = 0

'  Assumes Chilkat is unlocked. See Global Unlock Sample.

Dim token As New ChilkatJsonObject
success = token.LoadFile("qa_data/tokens/hotmail.json")
If (success <> 1) Then
    Debug.Print "Could not read qa_data/tokens/hotmail.json from the private working directory."
    Exit Sub
End If

If ((token.JsonTypeOf("access_token") <> 1) Or (token.StringOfEquals("access_token","",1) = 1)) Then
    Debug.Print "An OAuth access token is required. Authorize or refresh the account first."
    Exit Sub
End If

Dim mailbox As String
mailbox = "user@example.com"
Dim mailman As New ChilkatMailMan
mailman.SmtpHost = "smtp-mail.outlook.com"
mailman.SmtpPort = 587
mailman.SmtpSsl = 0
mailman.StartTLS = 1
mailman.RequireSslCertVerify = 1
'  Microsoft SMTP submission uses STARTTLS on port 587, not implicit TLS on 465.
mailman.SmtpUsername = mailbox
mailman.SmtpPassword = ""
mailman.OAuth2AccessToken = token.StringOf("access_token")

success = mailman.SmtpConnect()
If (success <> 1) Then
    Debug.Print "Could not establish the SMTP STARTTLS connection."
    Exit Sub
End If

success = mailman.SmtpAuthenticate()
success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    Debug.Print "SMTP authentication failed. Check token expiry, scope, mailbox, and account settings."
    Exit Sub
End If

Debug.Print "SMTP OAuth2 authentication succeeded; no message was sent."