Chilkat Examples

ChilkatHOME.NET Core C#Android™AutoItCC#C++Chilkat2-PythonCkPythonClassic ASPDataFlexDelphi ActiveXDelphi DLLGoJavaLianjaMono C#Node.jsObjective-CPHP ActiveXPHP ExtensionPerlPowerBuilderPowerShellPureBasicRubySQL ServerSwift 2Swift 3,4,5...TclUnicode CUnicode C++VB.NETVBScriptVisual Basic 6.0Visual FoxProXojo Plugin

Visual Basic 6.0 Examples

Web API Categories

ASN.1
AWS KMS
AWS Misc
Amazon EC2
Amazon Glacier
Amazon S3
Amazon S3 (new)
Amazon SES
Amazon SNS
Amazon SQS
Async
Azure Cloud Storage
Azure Key Vault
Azure Service Bus
Azure Table Service
Base64
Bounced Email
Box
CAdES
CSR
CSV
Certificates
Code Signing
Compression
DKIM / DomainKey
DNS
DSA
Diffie-Hellman
Digital Signatures
Dropbox
Dynamics CRM
EBICS
ECC
Ed25519
Email Object
Encryption
FTP
FileAccess
Firebase
GMail REST API
GMail SMTP/IMAP/POP
Geolocation
Google APIs
Google Calendar
Google Cloud SQL
Google Cloud Storage
Google Drive
Google Photos
Google Sheets
Google Tasks
Gzip
HTML-to-XML/Text
HTTP

HTTP Misc
IMAP
JSON
JSON Web Encryption (JWE)
JSON Web Signatures (JWS)
JSON Web Token (JWT)
Java KeyStore (JKS)
MHT / HTML Email
MIME
MS Storage Providers
Microsoft Graph
Misc
NTLM
OAuth1
OAuth2
OIDC
Office365
OneDrive
OpenSSL
Outlook
Outlook Calendar
Outlook Contact
PDF Signatures
PEM
PFX/P12
PKCS11
POP3
PRNG
REST
REST Misc
RSA
SCP
SCard
SFTP
SMTP
SSH
SSH Key
SSH Tunnel
ScMinidriver
SharePoint
SharePoint Online
Signing in the Cloud
Socket/SSL/TLS
Spider
Stream
Tar Archive
ULID/UUID
Upload
WebSocket
XAdES
XML
XML Digital Signatures
XMP
Zip
curl

 

 

 

(Visual Basic 6.0) Send Email Asynchronously using a Task

Send email asynchronously using the task object. Any Chilkat method (in any class/object) that involves network communications or lengthy processing will have an asynchronous version of the method. The asynchronous method has the same name as the synchronous method, but ends in "Async" and returns a Task object. The Task object can be run asynchronously on Chilkat's background thread pool.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for sending and receiving email.
Dim mailman As New ChilkatMailMan

' Set the SMTP server and any required settings.
mailman.SmtpHost = "smtp.mymailserver.com"
mailman.SmtpUsername = "myLogin"
mailman.SmtpPassword = "myPassword"
mailman.StartTLS = 1

' Create a new email object
Dim email As New ChilkatEmail

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
Dim success As Long
success = email.AddTo("Chilkat Admin","admin@chilkatsoft.com")

' Call the async version of the SendEmail method to return a task object.
' The task object is loaded, but is in the Inert state -- meaning it is
' not yet scheduled to run on Chilkat's background thread pool.
Dim task As ChilkatTask
Set task = mailman.SendEmailAsync(email)
If (mailman.LastMethodSuccess = 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' Schedule the task for running on the thread pool.  This changes the task's state
' from Inert to Live.
success = task.Run()
If (success <> 1) Then
    Debug.Print task.LastErrorText

    Exit Sub
End If

' The application is now free to do anything else
' while the email is being sent.

' For this example, we'll simply sleep and periodically
' check to see if the SendEmail if finished.  While checking
' however, we'll report on the progress.
Dim curPctDone As Long
curPctDone = 0
Do While task.Finished <> 1

    If (task.PercentDone <> curPctDone) Then
        curPctDone = task.PercentDone
        Debug.Print curPctDone & " percent done"
    End If

    ' Sleep 100 ms.
    task.SleepMs 100

Loop

' A finished task could be one that was canceled, aborted, or truly finished.  

' If the task was "canceled", it was canceled prior to actually starting.  This could
' happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
' background thread pool scheduler.  

' If the task was "aborted", it indicates that it was canceled while running in a background thread.  
' The ResultErrorText will likely indicate that the task was aborted.

' If the task "completed", then it ran to completion, but the actual success/failure of the method
' is determined by the result obtained via a GetResult* method.  (A "completed" task will
' have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
' been aborted or canceled:
If (task.StatusInt <> 7) Then
    Debug.Print "Task did not complete."
    Debug.Print "task status: " & task.Status

    Exit Sub
End If

' The SendEmail method returns a boolean.  Therefore, after the task is finished,
' we can get the boolean result by calling GetResultBool.  This is the return value had
' we called SendEmail synchronously.
success = task.GetResultBool()
If (success <> 1) Then
    ' The task's ResultErrorText contains what would have been in the LastErrorText property had
    ' the SendEmail method been called synchronously.
    Debug.Print task.ResultErrorText
Else
    Debug.Print "Email sent asynchronously."
End If

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    Debug.Print "Connection to SMTP server not closed cleanly."

End If


 

© 2000-2024 Chilkat Software, Inc. All Rights Reserved.