(Visual Basic 6.0) SII Chile - FRMA Signature Computation and Add to XML

Compute the FRMA signature of a <DA> element enclosed inside a <CAF> element of the XML to be signed.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Also see:  Compute the FRMT Signature and Add to XML

Dim xml As New ChilkatXml

' Load the unsigned XML that contains the following:

' <DTE version="1.0">
'   <Documento ID="F60T33">
'         <TED version="1.0">
'             <DD>
' 		...
'                 <CAF version="1.0">
'                     <DA>
' 			...
'                     </DA>
' 			... The FRMA will be added here ...
'                 </CAF>
'                 ...
'             </DD>
'             ... The FRMT will be added here in another example ...
'         </TED>
'   </Documento>
' </DTE>

Dim success As Long
success = xml.LoadXmlFile("qa_data/xml_dsig/sii_cl/test_0.xml")
If (success = 0) Then
    Debug.Print "Failed to load initial XML file."
    Exit Sub
End If

' Get a reference to the "DA" element
Dim daXml As ChilkatXml
Set daXml = xml.FindChild("Documento|TED|DD|CAF|DA")
If (xml.LastMethodSuccess = 0) Then
    Debug.Print "Failed to find DA element"
    Exit Sub
End If

'  We need to get the "flattened" DA XML where:
'    - No whitespace between elements.
'    - The 5 pre-defined entities are converted.
'    - The text is encoded in the ISO-8859-1 character set (Latin-1), 
Dim sbFlattened As New ChilkatStringBuilder
daXml.EmitCompact = 1
daXml.EmitXmlDecl = 0
success = daXml.GetXmlSb(sbFlattened)

' Compute the SHA-1 message digest of the iso-8859-1 byte representation, 
' and sign it with our RSA private key, getting the result in base64 format.

Dim privKey As New PrivateKey
success = privKey.LoadAnyFormatFile("qa_data/rsa/rsaPrivKey_pkcs8.pem","")
If (success = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim rsa As New ChilkatRsa
success = rsa.ImportPrivateKeyObj(privKey)

rsa.EncodingMode = "base64"
rsa.Charset = "iso-8859-1"
Dim sig As String
sig = rsa.SignStringENC(sbFlattened.GetAsString(),"sha1")

' Add the FRMA signature element to the XML.
xml.UpdateChildContent "Documento|TED|DD|CAF|FRMA",sig
success = xml.UpdateAttrAt("Documento|TED|DD|CAF|FRMA",1,"algoritmo","SHA1withRSA")

' See what we have:
xml.EmitCompact = 0
xml.EmitXmlDecl = 1
Debug.Print xml.GetXml()

success = xml.SaveXml("qa_data/xml_dsig/sii_cl/test_1.xml")