(Visual Basic 6.0) PDF Signature with Background Image (Seal/Stamp/etc.)

See more PDF Signatures Examples

Demonstrates how to sign a PDF with an appearance that includes a background image, such as a seal, stamp, etc.

Note: This example requires Chilkat v9.5.0.85 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim pdf As New ChilkatPdf

' Load a PDF to be signed.
' The "hello.pdf" is available at https://chilkatsoft.com/hello.pdf
Dim success As Long
success = pdf.LoadFile("qa_data/pdf/hello.pdf")
If (success = 0) Then
    Debug.Print pdf.LastErrorText
    Exit Sub
End If

' Options for signing are specified in JSON.
Dim json As New ChilkatJsonObject

' In most cases, the signingCertificateV2 and signingTime attributes are required.
success = json.UpdateInt("signingCertificateV2",1)
success = json.UpdateInt("signingTime",1)

' Put the signature on page 1, top left
success = json.UpdateInt("page",1)
success = json.UpdateString("appearance.y","top")
success = json.UpdateString("appearance.x","left")

' Use a font scale of 10.0
success = json.UpdateString("appearance.fontScale","10.0")

' In this example, the appearance of the digital signature will contain three lines:
' 1) The signing certificate's common name
' 2) The current date/time
' 3) Some arbitrary text.
' The keyword "cert_cn" is replaced with the Certificate's Subject Common Name.
' The keyword "current_dt" is replaced with the current date/time.
' Any number of appearance text lines can be added.
success = json.UpdateString("appearance.text[0]","Digitally signed by: cert_cn")
success = json.UpdateString("appearance.text[1]","current_dt")
success = json.UpdateString("appearance.text[2]","The crazy brown fox jumps over the lazy dog.")

' Load a JPG image to be shown with 30% opacity in the background.
' (the image must be in the JPG format)
' The sample university.jpb is available at https://example-code.com/images/university.jpg

Dim jpgData As New ChilkatBinData
success = jpgData.LoadFile("qa_data/jpg/university.jpg")
If (success = 0) Then
    Debug.Print "Failed to load the JPG image."
    Exit Sub
End If

success = pdf.SetSignatureJpeg(jpgData)
If (success = 0) Then
    Debug.Print pdf.LastErrorText
    Exit Sub
End If

' Specify that we want to display the JPG image in the center with 30% opacity.
success = json.UpdateString("appearance.image","custom-jpg")
success = json.UpdateString("appearance.imagePlacement","center")
success = json.UpdateString("appearance.imageOpacity","30")

' Load the signing certificate. (Use your own certificate.)
Dim cert As New ChilkatCert
success = cert.LoadPfxFile("qa_data/pfx/myPdfSigningCert.pfx","secret")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Tell the pdf object to use the certificate for signing.
success = pdf.SetSigningCert(cert)
If (success = 0) Then
    Debug.Print pdf.LastErrorText
    Exit Sub
End If

success = pdf.SignPdf(json,"qa_output/hello_signed.pdf")
If (success = 0) Then
    Debug.Print pdf.LastErrorText
    Exit Sub
End If

Debug.Print "The PDF has been successfully cryptographically signed."

' The appearance of the signature appears in Adobe Acrobat as shown below.
' The JPG is automatically scaled to the size of the signature based on the signature's font scale
' and number of text lines.