Visual Basic 6.0

Shopware 6 - Find Category by Name

See more Shopware 6 Examples

Find a category with a given name and get the id. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' Sends the following POST to find the category named "Test123"

' POST /api/v3/search/category
' {
'     "filter": [
'         { "type": "equals", "field": "name", "value": "Test123" }
'     ],
'     "includes": {
'         "category": ["id", "name"]
'     }
' }

' Create the above JSON.
' Use this online tool to generate code from sample JSON:
' Generate Code to Create JSON

Dim json As New ChilkatJsonObject
success = json.UpdateString("filter[0].type","equals")
success = json.UpdateString("filter[0].field","name")
success = json.UpdateString("filter[0].value","Test123")
success = json.UpdateString("includes.category[0]","id")
success = json.UpdateString("includes.category[1]","name")

' Load the access token previously obtained in Shopware 6 OAuth2 Client Credentials
Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/shopware6.json")

' This causes the "Authorization: Bearer <access_token>" header to be added.
http.AuthToken = jsonToken.StringOf("access_token")

' Note: If you get a 401 response status code, then fetch a new access token and retry.
Dim resp As New ChilkatHttpResponse
success = http.HttpJson("POST","https://my-shopware-6-shop.de/api/v3/search/category",json,"application/json",resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim sbResponseBody As New ChilkatStringBuilder
success = resp.GetBodySb(sbResponseBody)
Dim jResp As New ChilkatJsonObject
success = jResp.LoadSb(sbResponseBody)
jResp.EmitCompact = 0

Debug.Print "Response Body:"
Debug.Print jResp.Emit()

' If we get a 401 response, it may be that our access token expired and we need to fetch a new one.
Dim respStatusCode As Long
respStatusCode = resp.StatusCode
Debug.Print "Response Status Code = " & respStatusCode
If (respStatusCode >= 400) Then
    Debug.Print "Response Header:"
    Debug.Print resp.Header
    Debug.Print "Failed."
    Exit Sub
End If

' The response looks like this:
' Use the following online tool to generate parsing code from sample JSON:
' Generate Parsing Code from JSON

' {
'   "data": [
'     {
'       "id": "89c4131789fd422c8f00cf37bbb83330",
'       "type": "category",
'       "attributes": {
'         "name": "Test123",
'         "apiAlias": null
'       },
'       "links": {
'         "self": "https:\/\/***.de\/api\/v3\/category\/89c4131789fd422c8f00cf37bbb83330"
'       },
'       "relationships": [
'       ],
'       "meta": null
'     }
'   ],
'   "included": [
'   ],
'   "links": {
'     "self": "https:\/\/***.de\/api\/v3\/search\/category"
'   },
'   "meta": {
'     "totalCountMode": 0,
'     "total": 1
'   },
'   "aggregations": [
'   ]
' }

Dim numSearchResults As Long
numSearchResults = jResp.SizeOfArray("data")
If (numSearchResults <> 1) Then
    Debug.Print "numSearchResults = " & numSearchResults
    Debug.Print "Did not find the category, or unexpectedly found more than one with the same name."
    Exit Sub
End If

Dim categoryId As String
categoryId = jResp.StringOf("data[0].id")

Debug.Print "Category ID = " & categoryId