(Visual Basic 6.0) SharePoint -- Update the Contents of a File (PUT)

Demonstrates how to update the contents of a SharePoint file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

'  If SharePoint Windows classic authentication is used, then set the
'  Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

'  The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
'  If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
'  establish the cookie as shown at SharePoint Online Authentication

'  Indicate that we want a JSON reply
http.Accept = "application/json;odata=verbose"

'  Update /Documents/ChilkatTest/sample.docx with new content...
Dim req As New ChilkatHttpRequest
req.HttpVerb = "POST"
req.Path = "/_api/web/GetFileByServerRelativeUrl('/Documents/ChilkatTest/sample.docx')/$value"
'  Give the location of the file to be uploaded.
'  Note: The file is not loaded into memory at this point.  It is never fully loaded
'  into memory.  Instead, the file data is streamed directly from the file when
'  when the upload occurs.
success = req.StreamBodyFromFile("qa_data/msword/sample.docx")

'  We need to add a form digest value in the X-RequestDigest header field.
'  See this example for details on
'  how to get (and cache) a form digest value
req.AddHeader "X-RequestDigest","SHAREPOINT_FORM_DIGEST"

'  Also need to add this header..
req.AddHeader "X-HTTP-Method","PUT"

'  Upload..
Dim bUseTls As Long
bUseTls = 1
Dim resp As ChilkatHttpResponse
Set resp = http.SynchronousRequest("SHAREPOINT_HTTPS_DOMAIN",443,bUseTls,req)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

'  A successful update will return a 204 status code with an empty body.
'  A non-successful update will return a JSON response body..
If (resp.StatusCode <> 204) Then
    Debug.Print "Response status code = " & resp.StatusCode
    Dim json As New ChilkatJsonObject
    success = json.Load(resp.BodyStr)
    json.EmitCompact = 0
    Debug.Print json.Emit()
    Debug.Print "Failed"

    Exit Sub
End If

Debug.Print "Success."