(Visual Basic 6.0) Retrieve a Particular SharePoint List as JSON

See more SharePoint Examples

Downloads a particular SharePoint list and parses the JSON.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' -------------------------------------------------------------------------
' The following comments apply to SharePoint Windows classic authentication.
' -------------------------------------------------------------------------
' For example, imagine our SharePoint endpoint is https://xyzoffice.mycompany.com/
' The SHAREPOINT_NTLM_DOMAIN would be "mycompany.com"
' The SHAREPOINT_HTTPS_DOMAIN would be "xyzoffice.mycompany.com"
' Also, the SHAREPOINT_USERNAME would be just the name, not a full email address.
' for example, "chilkat" instead of "chilkat@mycompany.com"

Dim http As New ChilkatHttp

' If SharePoint Windows classic authentication is used, then set the 
' Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

' -------------------------------------------------------------------------
' The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
' If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
' establish the cookie as shown at SharePoint Online Authentication
' -------------------------------------------------------------------------

' Indicate that we want a JSON reply
http.Accept = "application/json;odata=verbose"
http.AcceptCharset = "utf-8"

' The contents of a SharePoint list can be downloaded by it's URI,
' which has the following URL format:
' https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/items
' 
' To get the URI's for all SharePoint lists, 
' See Get SharePoint Lists.

' Download the list like this (where the SHAREPOINT_DOCUMENTS_GUID is replaced with the actual GUID)
Dim sbJson As New ChilkatStringBuilder
Dim success As Long
success = http.QuickGetSb("https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/Lists(guid'SHAREPOINT_DOCUMENTS_GUID')/items",sbJson)
If (success <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim json As New ChilkatJsonObject
success = json.LoadSb(sbJson)
json.EmitCompact = 0

' Iterate over the items in this list.
Dim numItems As Long
numItems = json.SizeOfArray("d.results")
Debug.Print "Number of Items in this SharePoint List = " & numItems

Dim i As Long
i = 0
Do While i < numItems
    json.I = i

    Dim title As String
    title = json.StringOf("d.results[i].Title")
    Dim uri As String
    uri = json.StringOf("d.results[i].__metadata.uri")

    Debug.Print (i + 1) & ": " & title
    ' This is the URI for the Nth item in this list
    Debug.Print "URI: " & uri

    i = i + 1
Loop

' My output when testing is like what is shown below.

' I found that not every item has a Title,  but as viewed in a browser, I can see each of the item's name.
' (The number of items agrees with what I can interactively see in a browser.) The mystery of what
' is being shown for the name (or title) in the browser will be investigated further as Chilkat
' continues to explore the SharePoint API...

' 	Number of Items in this SharePoint List = 13
' 	1: Domain Name created for Exchange Docx
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(3)
' 	2: null
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(4)
' 	3: VCAC_RA_Design.docx
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(5)
' 	4: null
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(9)
' 	5: null
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(10)
' 	6: Architecture Briefv1
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(16)
' 	7: PowerPoint Presentation
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(17)
' 	8: null
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(18)
' 	9: null
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(19)
' 	10: null
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(20)
' 	11: FRC Summit Brief
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(21)
' 	12: VCAC DISA Brief 8-13-16
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(22)
' 	13: TEST PROCEDURE
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(23)
'