(Visual Basic 6.0) SharePoint -- Get Files in Root Folder

See more SharePoint Examples

Gets the list of files that exist in the root folder.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' -------------------------------------------------------------------------
' The following comments apply to SharePoint Windows classic authentication.
' -------------------------------------------------------------------------
' For example, imagine our SharePoint endpoint is https://xyzoffice.mycompany.com/
' The SHAREPOINT_NTLM_DOMAIN would be "mycompany.com"
' The SHAREPOINT_HTTPS_DOMAIN would be "xyzoffice.mycompany.com"
' Also, the SHAREPOINT_USERNAME would be just the name, not a full email address.
' for example, "chilkat" instead of "chilkat@mycompany.com"

Dim http As New ChilkatHttp

' If SharePoint Windows classic authentication is used, then set the 
' Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

' -------------------------------------------------------------------------
' The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
' If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
' establish the cookie as shown at SharePoint Online Authentication
' -------------------------------------------------------------------------

' Indicate that we want a JSON reply
http.Accept = "application/json;odata=verbose"
http.AcceptCharset = "utf-8"

' If your Sharepoint site is within a site collection, then use "https://SHAREPOINT_HTTPS_DOMAIN/sites/teamA/_api/web/GetFolderByServerRelativeUrl('/sites/teamA/')/Files" where "teamA" is the name of the site.
Dim sbJson As New ChilkatStringBuilder
Dim success As Long
success = http.QuickGetSb("https://SHAREPOINT_HTTPS_DOMAIN/_api/web/GetFolderByServerRelativeUrl('/')/Files",sbJson)
If (success <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim json As New ChilkatJsonObject
success = json.LoadSb(sbJson)

' Iterate over the results and get each file's name, size, and last-modified date/time.

Dim numFiles As Long
numFiles = json.SizeOfArray("d.results")
Debug.Print "Number of Files in the SharePoint root folder = " & numFiles

Dim lastMod As New CkDateTime
Dim dt As DtObj
Dim bLocal As Long
bLocal = 1

Dim i As Long
i = 0
Do While i < numFiles
    json.I = i

    Dim filename As String
    filename = json.StringOf("d.results[i].Name")
    Dim fileRelativeUri As String
    fileRelativeUri = json.StringOf("d.results[i].ServerRelativeUrl")
    Dim fileSize As Long
    fileSize = json.IntOf("d.results[i].Length")
    Dim sLastModified As String
    sLastModified = json.StringOf("d.results[i].TimeLastModified")

    Debug.Print (i + 1) & ": " & filename
    Debug.Print "    Relative URI: " & fileRelativeUri
    Debug.Print "    Size in Bytes: " & fileSize

    ' Show the last-modified date/time in the local timezone.
    success = lastMod.SetFromTimestamp(sLastModified)
    Set dt = lastMod.GetDtObj(bLocal)
    Debug.Print "    Last-Modified: " & dt.Day & "/" & dt.Month & "/" & dt.Year & " " & dt.Hour & ":" _
         & dt.Minute

    i = i + 1
Loop

' The output of this program when I tested it:

' 	Number of Files in the SharePoint root folder = 5
' 	1: Documentstester1.txt
' 	    Relative URI: /Documentstester1.txt
' 	    Size in Bytes: 17
' 	    Last-Modified: 6/4/2017 11:31
' 	2: Documents11_D42_Device_70_IP.xlsx
' 	    Relative URI: /Documents11_D42_Device_70_IP.xlsx
' 	    Size in Bytes: 17472
' 	    Last-Modified: 6/4/2017 10:54
' 	3: default.aspx
' 	    Relative URI: /default.aspx
' 	    Size in Bytes: 3960
' 	    Last-Modified: 26/10/2015 20:47
' 	4: DocumentsVCAC NEW Admin and RA bacgrounds.pptx
' 	    Relative URI: /DocumentsVCAC NEW Admin and RA bacgrounds.pptx
' 	    Size in Bytes: 11867024
' 	    Last-Modified: 6/4/2017 10:51
' 	5: DocumentsVCAC_Installer_Web_Sites_Installation.docx
' 	    Relative URI: /DocumentsVCAC_Installer_Web_Sites_Installation.docx
' 	    Size in Bytes: 529482
' 	    Last-Modified: 6/4/2017 11:0