(Visual Basic 6.0) SharePoint -- Get Files in Documents Folder

See more SharePoint Examples

Gets the list of files that exist in the /Documents folder.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' -------------------------------------------------------------------------
' The following comments apply to SharePoint Windows classic authentication.
' -------------------------------------------------------------------------
' For example, imagine our SharePoint endpoint is https://xyzoffice.mycompany.com/
' The SHAREPOINT_NTLM_DOMAIN would be "mycompany.com"
' The SHAREPOINT_HTTPS_DOMAIN would be "xyzoffice.mycompany.com"
' Also, the SHAREPOINT_USERNAME would be just the name, not a full email address.
' for example, "chilkat" instead of "chilkat@mycompany.com"

Dim http As New ChilkatHttp

' If SharePoint Windows classic authentication is used, then set the 
' Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

' -------------------------------------------------------------------------
' The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
' If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
' establish the cookie as shown at SharePoint Online Authentication
' -------------------------------------------------------------------------

' Indicate that we want a JSON reply
http.Accept = "application/json;odata=verbose"
http.AcceptCharset = "utf-8"

' If your Sharepoint site is within a site collection, then use "https://SHAREPOINT_HTTPS_DOMAIN/sites/teamA/_api/web/GetFolderByServerRelativeUrl('/sites/teamA/Documents')/Files" where "teamA" is the name of the site.
Dim sbJson As New ChilkatStringBuilder
Dim success As Long
success = http.QuickGetSb("https://SHAREPOINT_HTTPS_DOMAIN/_api/web/GetFolderByServerRelativeUrl('/Documents')/Files",sbJson)
If (success <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim json As New ChilkatJsonObject
success = json.LoadSb(sbJson)

' Iterate over the results and get each file's name, size, and last-modified date/time.

Dim numFiles As Long
numFiles = json.SizeOfArray("d.results")
Debug.Print "Number of Files in the SharePoint /Documents folder = " & numFiles

Dim lastMod As New CkDateTime
Dim dt As DtObj
Dim bLocal As Long
bLocal = 1

Dim i As Long
i = 0
Do While i < numFiles
    json.I = i

    Dim filename As String
    filename = json.StringOf("d.results[i].Name")
    Dim fileRelativeUri As String
    fileRelativeUri = json.StringOf("d.results[i].ServerRelativeUrl")
    Dim fileSize As Long
    fileSize = json.IntOf("d.results[i].Length")
    Dim sLastModified As String
    sLastModified = json.StringOf("d.results[i].TimeLastModified")

    Debug.Print (i + 1) & ": " & filename
    Debug.Print "    Relative URI: " & fileRelativeUri
    Debug.Print "    Size in Bytes: " & fileSize

    ' Show the last-modified date/time in the local timezone.
    success = lastMod.SetFromTimestamp(sLastModified)
    Set dt = lastMod.GetDtObj(bLocal)
    Debug.Print "    Last-Modified: " & dt.Day & "/" & dt.Month & "/" & dt.Year & " " & dt.Hour & ":" _
         & dt.Minute

    i = i + 1
Loop

' The output of this program when I tested it:

' 	Number of Files in the SharePoint /Documents folder = 13
' 	1: VCAC_DISA_brief_8_13_16.pdf
' 	    Relative URI: /Documents/VCAC_DISA_brief_8_13_16.pdf
' 	    Size in Bytes: 5571942
' 	    Last-Modified: 14/8/2016 21:32
' 	2: Test Procedure Self-Registration Kiosk.docx
' 	    Relative URI: /Documents/Test Procedure Self-Registration Kiosk.docx
' 	    Size in Bytes: 26568
' 	    Last-Modified: 16/1/2017 10:46
' 	3: VCAC_Architecture_Brief_8_29_15.pptx
' 	    Relative URI: /Documents/VCAC_Architecture_Brief_8_29_15.pptx
' 	    Size in Bytes: 28756136
' 	    Last-Modified: 17/3/2016 15:32
' 	4: D42_Device_70_IP.xlsx
' 	    Relative URI: /Documents/D42_Device_70_IP.xlsx
' 	    Size in Bytes: 17060
' 	    Last-Modified: 14/3/2016 21:22
' 	5: Domain Name created for Exchange.docx
' 	    Relative URI: /Documents/Domain Name created for Exchange.docx
' 	    Size in Bytes: 80651
' 	    Last-Modified: 16/1/2017 11:8
' 	6: VCAC_Architecture_Brief_8_29_15.pdf
' 	    Relative URI: /Documents/VCAC_Architecture_Brief_8_29_15.pdf
' 	    Size in Bytes: 5814495
' 	    Last-Modified: 17/3/2016 15:30
' 	7: D42_Device_70_IP223.xlsx
' 	    Relative URI: /Documents/D42_Device_70_IP223.xlsx
' 	    Size in Bytes: 17109
' 	    Last-Modified: 16/1/2017 12:1
' 	8: image_VCAC.png
' 	    Relative URI: /Documents/image_VCAC.png
' 	    Size in Bytes: 4825795
' 	    Last-Modified: 21/3/2016 14:13
' 	9: FRC_Summit_brief.pdf
' 	    Relative URI: /Documents/FRC_Summit_brief.pdf
' 	    Size in Bytes: 2202216
' 	    Last-Modified: 14/8/2016 21:31
' 	10: VCAC_RA_Design.docx
' 	    Relative URI: /Documents/VCAC_RA_Design.docx
' 	    Size in Bytes: 32278
' 	    Last-Modified: 15/1/2017 22:44
' 	11: VCAC_PEO_EIS_Brief_3_23_16.pdf
' 	    Relative URI: /Documents/VCAC_PEO_EIS_Brief_3_23_16.pdf
' 	    Size in Bytes: 7239114
' 	    Last-Modified: 22/3/2016 17:50
' 	12: VCAC-document.docx
' 	    Relative URI: /Documents/VCAC-document.docx
' 	    Size in Bytes: 21082
' 	    Last-Modified: 15/1/2017 22:44
' 	13: Engineering_Drawing (sample).jpg
' 	    Relative URI: /Documents/Engineering_Drawing (sample).jpg
' 	    Size in Bytes: 97638
' 	    Last-Modified: 22/3/2016 17:51