(Visual Basic 6.0) SFTP use Cert's Private Key from PFX (.pfx/.p12)

Demonstrates how to use the private key associated with a certificate from a .pfx/.p12 file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim cert As New ChilkatCert

Dim pfxFilepath As String
pfxFilepath = "qa_data/pfx/my.pfx"
Dim pfxPassword As String
pfxPassword = "secret"

' A PFX typically contains certificates in the chain of authentication.
' The Chilkat cert object will choose the certificate w/
' private key farthest from the root authority cert.
' To access all the certificates in a PFX, use the 
' Chilkat certificate store object instead.
Dim success As Long
success = cert.LoadPfxFile(pfxFilepath,pfxPassword)
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Get the private key.  
Dim privKey As PrivateKey
Set privKey = cert.ExportPrivateKey()
If (cert.LastMethodSuccess = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

Dim privKeyPem As String
privKeyPem = privKey.GetPkcs8Pem()
If (privKey.LastMethodSuccess = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim sshKey As New ChilkatSshKey
success = sshKey.FromOpenSshPrivateKey(privKeyPem)
If (success = 0) Then
    Debug.Print sshKey.LastErrorText
    Exit Sub
End If

' Connect to an SSH/SFTP server
Dim sftp As New ChilkatSFtp
success = sftp.Connect("sftp.example.com",22)
If (success = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

' Authenticate with the SSH server using a username + private key.
' (The private key serves as the password.  The username identifies
' the SSH user account on the server.)
success = sftp.AuthenticatePk("mySshLogin",sshKey)
If (success = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

Debug.Print "OK, the connection and authentication with the SSH server is completed."

' This example is only to show the connection + authentication using a private key associated with a certificate in the Windows certificate store...