Visual Basic 6.0
SendRawEmail (HTML Email with PDF Attachment)

Demonstrates how to use the SES SendRawEmail action to send an email with an attachment. Note: The total size of an SES email cannot exceed 10MB.
See SES SendRawEmail for more information.
Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0
Visual Basic 6.0
Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Let's first prepare the email to be sent..
Dim email As New ChilkatEmail
email.Charset = "utf-8"
email.Subject = "Test email with PDF attachment."
email.SetHtmlBody "<html><body><p>This is a test <b>HTML email with a PDF attachment</b></p></body></html>"

' The AddFileAttachment method returns the content-type selected based on the 
' file extension.   This example has no need of using the return value..
Dim contentType As String
contentType = email.AddFileAttachment("qa_data/pdf/fishing.pdf")
If (email.LastMethodSuccess <> 1) Then
    Debug.Print email.LastErrorText
    Exit Sub
End If

' Add the From header, and some recipients.
' The From address should be an email address verified for use
' as a sender for your Amazon SES account.
' The From address will also be the Source parameter for the SES SendRawEmail request.
email.From = "Chilkat Software <admin@chilkatdownload.com>"

' Add recipients...
' Note: We DO NOT add BCC recipients to the email.  A BCC address should not be
' present in the MIME header of the email (otherwise it would not be "blind" because
' other recipients would be able to see it).
' These same addresses will be added as parameters to the SendRawEmail request.
' (BCC addresses are added as parameters at that time.)
success = email.AddTo("Mr. Simulator","success@simulator.amazonses.com")
success = email.AddCC("Chilkat Support","support@chilkatsoft.com")
success = email.AddCC("Some Yahoo","somebody@yahoo.com")

' Get the MIME of the email to be sent.
Dim mimeStr As String
mimeStr = email.GetMime()

' We'll need the MIME base64 encoded for the SES REST request..
Dim crypt As New ChilkatCrypt2
Dim mimeBase64 As String
mimeBase64 = crypt.EncodeString(mimeStr,"utf-8","base64")

' OK.. our MIME email is prepared.  Now use Chilkat REST to send it..

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server.
' such as https://email.us-west-2.amazonaws.com/
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("email.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "ses"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","SendRawEmail")

success = rest.AddQueryParam("RawMessage.Data",mimeBase64)

' Add up to 100 TO, CC, and BCC recipients.
' If your SES account is still in the sandbox, you also must verify every recipient email address except for the recipients 
' provided by the Amazon SES mailbox simulator. (See http://docs.aws.amazon.com/ses/latest/DeveloperGuide/mailbox-simulator.html)
success = rest.AddQueryParam("Destination.ToAddresses.member.1","success@simulator.amazonses.com")
' Please do not test by sending email to Chilkat (Thank You!)
' Please do not test by sending email to Chilkat (Thank You!)
' Please do not test by sending email to Chilkat (Thank You!)
success = rest.AddQueryParam("Destination.CcAddresses.member.1","support@chilkatsoft.com")
success = rest.AddQueryParam("Destination.CcAddresses.member.2","somebody@yahoo.com")
success = rest.AddQueryParam("Destination.BccAddresses.member.1","somebody@gmail.com")

success = rest.AddQueryParam("Source","admin@chilkatdownload.com")

' Because there may be a large amount of data in the query params, use a POST
' where the params are sent in the body of the HTTP Request.
Dim responseXml As String
responseXml = rest.FullRequestFormUrlEncoded("POST","/")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = " & rest.ResponseStatusCode
    Debug.Print "response status text = " & rest.ResponseStatusText
    Debug.Print "response header: " & rest.ResponseHeader
    Debug.Print "response body: " & responseXml
    Exit Sub
End If

' Examine the successful XML response.
Dim xml As New ChilkatXml
success = xml.LoadXml(responseXml)
Debug.Print xml.GetXml()

' To get the MessageId
Debug.Print "MessageId: " & xml.ChilkatPath("SendEmailResult|MessageId|*")

' A sample successful response:
' <?xml version="1.0" encoding="utf-8" ?>
' <SendEmailResponse xmlns="http://ses.amazonaws.com/doc/2010-12-01/">
'     <SendEmailResult>
'         <MessageId>010101579081d2c1-043c693f-5a23-4c64-a8c1-66187d3725a0-000000</MessageId>
'     </SendEmailResult>
'     <ResponseMetadata>
'         <RequestId>e2b5b480-8a4e-11e6-85cd-21b1f1f6d432</RequestId>
'     </ResponseMetadata>
' </SendEmailResponse>